home *** CD-ROM | disk | FTP | other *** search
/ Almathera Ten Pack 3: CDPD 3 / Almathera Ten on Ten - Disc 3: CDPD3.iso / scope / 201-220 / scopedisk216 / popupmenu / source.lha / PopUpMenu.a < prev    next >
Encoding:
Text File  |  1991-10-25  |  82.2 KB  |  3,129 lines
  1.            opt      l+,c+,d+,y+
  2.            opt      ow1+,ow2+,ow3+,ow4+,ow5+,ow6+
  3.  
  4.            INCDIR ":Pspråk/asm/include/"
  5.  
  6.            INCLUDE      "exec/types.i"
  7.            INCLUDE      "PopUpMenu.i"
  8.  
  9.            xref      @FixDown     * In overlay root
  10.            xref      @QueTimer     * In overlay root
  11.            xref      @Mystrlen     * In overlay root
  12.  
  13.            xref      _PopUpSemaphore
  14.  
  15.            xdef      @PopUpMenu
  16.  
  17.  
  18. VBORDERSIZE    EQU      4
  19. HBORDERSIZE    EQU      2
  20. OVERLAP        EQU      8
  21. POPUPMENUDONE  EQU      0
  22. NULL           EQU      0
  23. MENUNULL       EQU     -1
  24. ITEMWINDOW     EQU      0
  25. ITEMFILL       EQU      0
  26. WORD_MAX       EQU      $7fff
  27. WORD_MIN       EQU      $8000
  28.  
  29.            section      text,code
  30. **********************************************
  31. * PopUpMenu(InputSignals)   (A3)             *
  32. *                         *
  33. * Input:                     *
  34. *   InputSignals  - Inputhandler signals.    *
  35. * Output:                     *
  36. *   none                     *
  37. * Functions:                     *
  38. *   FindWindow, InitGlobals, OpenMenuWindow, *
  39. *   QueTimer, SelectItem, FinalSelect,         *
  40. *   SwapBits, FindWindow, RemoveBitMap,      *
  41. *   CloseItemWindow, TellWindow          *
  42. **********************************************
  43. @PopUpMenu:    MOVEM.L     D2-D7/A2-A3/A5-A6,-(SP)
  44.  
  45. * ------------ ObtainSemaphore(&PopUpSemaphore)
  46.            LEA     _PopUpSemaphore,A0
  47.            MOVEA.L     (A4),A6       * SysBase
  48.            JSR     _LVOObtainSemaphore(A6)
  49.  
  50. * ------------ Is Window still open ?
  51.            JSR     @FindWindow(PC)
  52.            TST.W     D0
  53.            BEQ.W     Abort
  54.  
  55. * ------------ Lock the screen.
  56.            MOVEA.L     _Screen(A4),A2
  57.            ADDA.W     #sc_LayerInfo,A2
  58.            MOVEA.L     A2,A0
  59.            MOVEA.L     _LayersBase(A4),A6
  60.            JSR     _LVOLockLayers(A6)
  61.  
  62. * ------------ Init the global variables
  63. * ------------ Menues = ActiveWindow->MenuStrip
  64.            MOVEA.L     _ActiveWindow(A4),A0
  65.            MOVE.L     wd_MenuStrip(A0),_Menues(A4)
  66.  
  67. * ------------ ActiveWindow->Flags |= MENUSTATE
  68.            BSET     #MENUSTATEBIT,wd_Flags+2(A0)
  69.  
  70. * ------------ ItemWindow.BitMapOk = FALSE
  71.            MOVEQ.L     #FALSE,D0
  72.            MOVE.W     D0,_ItemWindow+wwd_BitMapOk(A4)
  73.  
  74. * ------------ SubWindow.BitMapOk = FALSE
  75.            MOVE.W     D0,_SubWindow+wwd_BitMapOk(A4)
  76.  
  77. * ------------ MenuWindow.BitMapOk = FALSE
  78.            MOVE.W     D0,_MenuWindow+wwd_BitMapOk(A4)
  79.  
  80. * ------------ CurrentMenuNr = 0
  81.            MOVE.W     D0,_CurrentMenuNr(A4)
  82.  
  83. * ------------ MenuWindow.Current = NULL
  84.            MOVE.L     D0,_MenuWindow+wwd_Current(A4)
  85.  
  86. * ------------ ItemWindow.Current = NULL
  87.            MOVE.L     D0,_ItemWindow+wwd_Current(A4)
  88.  
  89. * ------------ SubWindow.Current = NULL
  90.            MOVE.L     D0,_SubWindow+wwd_Current(A4)
  91.  
  92. * ------------ ScreenType = (Screen->ViewPort.Modes & HIRES) == 0
  93.            MOVEA.L     _Screen(A4),A5
  94.            BTST     #7,sc_ViewPort+vp_Modes(A5)  ********************
  95.            BNE.B     1$
  96.            MOVEQ.L     #TRUE,D0
  97. 1$           MOVE.W     D0,_ScreenType(A4)
  98.  
  99. * ------------ InitRastPort(&Rp)
  100.            LEA     _Rp(A4),A1
  101.            MOVEA.L     _GfxBase(A4),A6
  102.            JSR     _LVOInitRastPort(A6)
  103.  
  104. * ------------ SetFont(&Rp,Screen->RastPort.Font)
  105.            LEA     _Rp(A4),A1
  106.            MOVEA.L     sc_RastPort+rp_Font(A5),A0
  107.            JSR     _LVOSetFont(A6)
  108.  
  109. * ------------ Rp.BitMap = &Screen->BitMap
  110.            ADDA.W     #sc_BitMap,A5
  111.            MOVE.L     A5,_Rp+rp_BitMap(A4)
  112.  
  113. * ------------ MenuFontSize = Rp.TxHeight + 2
  114.            MOVE.W     _Rp+rp_TxHeight(A4),D0
  115.            ADDQ.W     #2,D0
  116.            MOVE.W     D0,_MenuFontSize(A4)
  117.  
  118. * ------------ Any menues at all ?
  119.            TST.L     _Menues(A4)
  120.            BEQ.W     NoMenues
  121.  
  122. * ------------ Same menues as last time ?
  123.            MOVEQ.L     #0,D0
  124.            MOVEA.L     _ActiveWindow(A4),A0
  125.            CMPA.L     _LastWindow(A4),A0
  126.            BNE.B     OpenMenues
  127.  
  128. * ------------ Yes: Start at last menu selection.
  129.            MOVE.W     _LastSelectedNum(A4),D0
  130.            BEQ.B     OpenMenues
  131.            SUBQ.W     #1,D0
  132.            MULU.W     _MenuFontSize(A4),D0
  133.  
  134. * ------------ Open the menues.
  135. OpenMenues:    JSR     @OpenMenuWindow(PC)
  136.            TST.W     D0
  137.            BEQ.W     NoMenues
  138.  
  139. * ------------ MenuButtonSignals = MenuUpSig | MenuDownSig
  140.            MOVE.L     sd_MenuUpSig(A3),D6
  141.            OR.L     sd_MenuDownSig(A3),D6
  142.  
  143. * ------------ MouseMovedSignal = MouseMovedSig
  144.            MOVE.L     sd_MouseMovedSig(A3),D5
  145.  
  146. * ------------ ButtonSignals = MenuButtonSignals | SelectDownSig
  147.            MOVE.L     D6,D4
  148.            OR.L     sd_SelectDownSig(A3),D4
  149.  
  150. * ------------ Waiting = FALSE
  151.            MOVEQ.L     #FALSE,D3
  152.  
  153. * ------------ No selections done so far.
  154. * ------------ MenuNumber = LastSelected = MENUNULL;
  155.            MOVEQ.L     #MENUNULL,D7
  156.            MOVE.W     D7,_LastSelected(A4)
  157.  
  158. * ------------ Clear old timermessages and set mousemoved signal.
  159. * ------------ SetSignal(MouseMovedSignal,TimerSignal | MouseMovedSignal)
  160.            MOVE.L     D5,D0
  161.            MOVE.L     _TimerSignal(A4),D1
  162.            OR.L     D5,D1
  163.            MOVEA.L     (A4),A6       * SysBase
  164.            JSR     _LVOSetSignal(A6)
  165.  
  166. * ------------ Is the timer already running.
  167. * ------------ CheckIO(TimerReqBlock)
  168.            MOVEA.L     _TimerReqBlock(A4),A1
  169.            JSR     _LVOCheckIO(A6)
  170.            TST.L     D0
  171.            BNE.B     IOReady
  172.  
  173. * ------------ Yes: wait for the time.
  174. * ------------ WaitIO(TimerReqBlock)
  175.            MOVEA.L     _TimerReqBlock(A4),A1
  176.            JSR     _LVOWaitIO(A6)
  177.  
  178. * ------------ Remove the message.
  179.            MOVEA.L     _TimerPort(A4),A0
  180.            JSR     _LVOGetMsg(A6)
  181.  
  182. * ------------ Start up the timer.
  183. IOReady:       JSR     @QueTimer(PC)
  184.  
  185. * ------------ Main loop starts here.
  186. * ------------ SignalBits = Wait(MouseMovedSignal | ButtonSignals | TimerSignal)
  187. WaitNextSig:   MOVE.L     D5,D0
  188.            OR.L     D4,D0
  189.            OR.L     _TimerSignal(A4),D0
  190.            MOVEA.L     (A4),A6       * SysBase
  191.            JSR     _LVOWait(A6)
  192.            MOVE.L     D0,D2
  193.  
  194.            MOVEA.L     _Screen(A4),A0
  195. *********************************************
  196. * D0 = SignalBits      A2 = LayerInfo    *
  197. * D2 = SignalBits      A3 = InputSignals *
  198. * D3 = Waiting          A6 = ExecBase     *
  199. * D4 = ButtonSignals      A0 = Screen        *
  200. * D5 = MouseMovedSignal             *
  201. * D6 = MenuButtonSignal             *
  202. * D7 = MenuNumber                *
  203. *********************************************
  204. * ------------ Mouse moved or Button pressed ?
  205.            MOVE.L     D5,D1
  206.            OR.L     D4,D1
  207.            AND.L     D0,D1
  208.            BEQ.W     NoButton      * No
  209.  
  210. * ------------ Waiting = FALSE
  211.            MOVEQ.L     #FALSE,D3
  212.  
  213. * ------------ Clickmenues ?
  214.            BTST     #CLICKMENUES,_Options(A4)
  215.            BEQ.B     CheckMove     * No
  216.  
  217. * ------------ Select button pressed ?
  218.            MOVE.L     sd_SelectDownSig(A3),D1
  219.            AND.L     D1,D0
  220.            BEQ.B     CheckButtons  * No
  221.  
  222. * ------------ Clear select button signal.
  223.            EOR.L     D1,D2
  224.  
  225. * ------------ Do selection.
  226.            MOVE.W     sc_MouseX(A0),_MouseX(A4)
  227.            MOVE.W     sc_MouseY(A0),_MouseY(A4)
  228.  
  229. * ------------ SelectItem() == TRUE ?
  230.            JSR     @SelectItem(PC)
  231.            TST.W     D0
  232.            BEQ.B     CheckButtons  * No
  233.  
  234. * ------------ MenuNumber = LastSelected = FinalSelect()
  235.            JSR     @FinalSelect(PC)
  236.            MOVE.W     D0,D7
  237.            MOVE.W     D0,_LastSelected(A4)
  238.            BRA.W     NoMoreSel
  239.  
  240. * ------------ MouseX = Screen->MouseX
  241. * ------------ MouseY = Screen->MouseY
  242. CheckMove:     MOVE.W     sc_MouseX(A0),D0
  243.            MOVE.W     sc_MouseY(A0),D1
  244.            CMP.W     _MouseX(A4),D0
  245.            BNE.B     MouseMoved
  246.            CMP.W     _MouseY(A4),D1
  247.            BEQ.B     CheckButtons
  248.  
  249. MouseMoved:    MOVE.W     D0,_MouseX(A4)
  250.            MOVE.W     D1,_MouseY(A4)
  251.  
  252. * ------------ Select the item under the mousepointer.
  253.            JSR     @SelectItem(PC)
  254.  
  255. * ------------ Any button pressed ?
  256. CheckButtons:  MOVE.L     D2,D0
  257.            AND.L     D4,D0
  258.            BEQ.B     NoButton
  259.  
  260. * ------------ Find MENUPICK value for selected item.
  261.            JSR     @FinalSelect(PC)
  262.  
  263. * ------------ Something selected ?  (New 4.1)
  264.            CMPI.W     #MENUNULL,D0
  265.            BEQ.B     NotSelected
  266.  
  267.            MOVE.W     D4,-(SP)
  268.            MOVE.W     D0,D4
  269.  
  270.            MOVE.W     _LastSelected(A4),D1
  271. **********************************************
  272. * D0 = Selected        A2 = LayerInfo    *
  273. * D1 = LastSelected       A3 = InputSignals *
  274. * D2 = SignalBits       A6 = ExecBase     *
  275. * D3 = Waiting                     *
  276. * D4 = Selected                  *
  277. * D5 = MouseMovedSignal              *
  278. * D6 = MenuButtonSignal              *
  279. * D7 = MenuNumber                 *
  280. **********************************************
  281. * ------------ Same item selected as last time ?
  282.            CMP.W     D0,D1
  283.            BEQ.B     SameItem
  284.  
  285. * ------------ First selection ?
  286.            CMPI.W     #MENUNULL,D7
  287.            BNE.B     MultipSelect
  288.  
  289. * ------------ MenuNumber = Selected
  290.            MOVE.W     D4,D7
  291.            BRA.B     SelectionDone
  292.  
  293. * ------------ ItemAddress(Menues,LastSelected)->NextSelect = Selected
  294. MultipSelect:  MOVEQ.L     #0,D0
  295.            MOVE.W     D1,D0
  296.            MOVEA.L     _Menues(A4),A0
  297.            MOVEA.L     _IntuitionBase(A4),A6
  298.            JSR     _LVOItemAddress(A6)
  299.            MOVEA.L     D0,A0
  300.            MOVE.W     D4,mi_NextSelect(A0)
  301.  
  302. * ------------ LastSelected = Selected
  303. SelectionDone: MOVE.W     D4,_LastSelected(A4)
  304. SameItem:      MOVE.W     (SP)+,D4
  305.  
  306. * ------------ Selected with menubutton ?
  307. NotSelected:   MOVE.L     D2,D0
  308.            AND.L     D6,D0
  309.            BNE.W     NoMoreSel
  310.  
  311. ********************************************
  312. * D2 = SignalBits     A2 = LayerInfo    *
  313. * D3 = Waiting         A3 = InputSignals *
  314. * D4 = ButtonSignals               *
  315. * D5 = MouseMovedSignal            *
  316. * D6 = MenuButtonSignal            *
  317. * D7 = MenuNumber               *
  318. ********************************************
  319. * ------------ Timer ?
  320. NoButton:      MOVE.L     D2,D0
  321.            AND.L     _TimerSignal(A4),D0
  322.            BEQ.W     WaitNextSig
  323.  
  324. * ------------ Remove the message.
  325.            MOVEA.L     _TimerPort(A4),A0
  326.            MOVEA.L     (A4),A6       * SysBase
  327.            JSR     _LVOGetMsg(A6)
  328.  
  329. * ------------ 2 TimerSignals in a row ?
  330.            TST.W     D3
  331.            BEQ.B     NoLockUp
  332.  
  333. * ------------ The input.device has stopped.
  334. * ------------ Remove everything from the screen.
  335.            LEA     _SubWindow(A4),A0
  336.            JSR     @SwapBits(PC)
  337.            LEA     _ItemWindow(A4),A0
  338.            JSR     @SwapBits(PC)
  339.            LEA     _MenuWindow(A4),A0
  340.            JSR     @SwapBits(PC)
  341.  
  342. * ------------ Unlock the screen.
  343.            MOVEA.L     A2,A0
  344.            MOVEA.L     _LayersBase(A4),A6
  345.            JSR     _LVOUnlockLayers(A6)
  346.  
  347. * ------------ Wait for the input.device.
  348.            MOVE.L     D5,D0
  349.            MOVEA.L     (A4),A6       * SysBase
  350.            JSR     _LVOWait(A6)
  351.  
  352. * ------------ Is the window still open ?
  353.            JSR     @FindWindow(PC)
  354.            TST.W     D0
  355.            BNE.B     OKToLock
  356.  
  357. * ------------ No: the window is gone. Abort.
  358.            LEA     _SubWindow(A4),A0
  359.            JSR     @RemoveBitMap(PC)
  360.            LEA     _ItemWindow(A4),A0
  361.            JSR     @RemoveBitMap(PC)
  362.            LEA     _MenuWindow(A4),A0
  363.            JSR     @RemoveBitMap(PC)
  364.            BRA.B     Abort
  365.  
  366. * ------------ Lock the screen again.
  367. OKToLock:      MOVEA.L     A2,A0
  368.            MOVEA.L     _LayersBase(A4),A6
  369.            JSR     _LVOLockLayers(A6)
  370.  
  371. * ------------ Put everything back on the screen.
  372.            LEA     _MenuWindow(A4),A0
  373.            JSR     @SwapBits(PC)
  374.            LEA     _ItemWindow(A4),A0
  375.            JSR     @SwapBits(PC)
  376.            LEA     _SubWindow(A4),A0
  377.            JSR     @SwapBits(PC)
  378.  
  379. * ------------ Start a new timer.
  380. NoLockUp:      JSR     @QueTimer(PC)
  381.  
  382. * ------------ Waiting = !Waiting
  383.            NEG.W     D3           * 3.7
  384.            ADDQ.W     #1,D3           * 3.7
  385.            BRA.W     WaitNextSig
  386.  
  387. * ------------ Selections done.
  388. * ------------ Close all windows.
  389. NoMoreSel:     JSR     @CloseSubWindow(PC)
  390.            JSR     @CloseItemWindow(PC)
  391.            JSR     @CloseMenuWindow(PC)
  392.  
  393. * ------------ Remember the selection for next time.
  394. NoMenues:      MOVEA.L     _ActiveWindow(A4),A0
  395.            MOVE.L     A0,_LastWindow(A4)
  396.  
  397. * ------------ ActiveWindow->Flags &= ~MENUSTATE
  398.            BCLR     #MENUSTATEBIT,wd_Flags+2(A0)
  399.  
  400. * ------------ Unlock the screen.
  401.            MOVEA.L     A2,A0
  402.            MOVEA.L     _LayersBase(A4),A6
  403.            JSR     _LVOUnlockLayers(A6)
  404.  
  405. * ------------ Tell the window the good news (MENUPICK).
  406.            MOVEA.L     A3,A0
  407.            MOVE.L     D7,D0
  408.            JSR     @TellWindow(PC)
  409.  
  410. * ------------ ReleaseSemaphore(&PopUpSemaphore);
  411. Abort:           LEA     _PopUpSemaphore,A0
  412.            MOVEA.L     (A4),A6       * SysBase
  413.            JSR     _LVOReleaseSemaphore(A6)
  414.  
  415. * ------------ FixDown(InputSignals)
  416.            MOVEA.L     A3,A0
  417.            JSR     @FixDown(PC)
  418.  
  419. * ------------ Free the sorted menulist      * New 3.42
  420.            LEA     _SortRemember(A4),A0
  421.            MOVEQ.L     #TRUE,D0
  422.            MOVEA.L     _IntuitionBase(A4),A6
  423.            JSR     _LVOFreeRemember(A6)
  424.  
  425.            MOVEM.L     (SP)+,D2-D7/A2-A3/A5-A6
  426.            RTS
  427.  
  428. ************************************************
  429. * FindMenuPtr(Number) - Find Menu structure.   *
  430. *                           *
  431. * Input:                       *
  432. *   Number.W - Number of the menu to look for. *
  433. * Output:                       *
  434. *   return - Ptr to the Menu structure.        *
  435. ************************************************
  436. @FindMenuPtr:    MOVEA.L   _MenuSorted+ms_Next(A4),A0
  437.  
  438. 1$        SUBQ.W      #1,D0
  439.         BEQ.B      2$
  440.  
  441.         MOVEA.L   (A0),A0     * ms_Next
  442.         MOVE.L      A0,D1
  443.         BNE.B      1$
  444.         MOVEQ.L   #NULL,D0
  445.         RTS
  446.  
  447. 2$        MOVE.L      ms_MenuPtr(A0),D0
  448.         RTS
  449.  
  450. ************************************************
  451. * FindItemNr(Item,ItemList) - Find nr of item. *
  452. *                           *
  453. * Input:                       *
  454. *   Item - Item to look for.               *
  455. *   ItemList - all items on same level.        *
  456. * Output:                       *
  457. *   return - Nr of Item.               *
  458. ************************************************
  459. * ------------ Count = 0
  460. @FindItemNr:   MOVEQ.L     #0,D0
  461.  
  462. * ------------ ItemList == NULL ?
  463. 1$           MOVE.L     A1,D1
  464.            BEQ.B     2$
  465.  
  466. * ------------ ItemList == Item ?
  467.            CMPA.L     A0,A1
  468.            BEQ.B     3$
  469.  
  470. * ------------ Count++
  471.            ADDQ.W     #1,D0
  472.  
  473. * ------------ ItemList = ItemList->NextItem
  474.            MOVEA.L     (A1),A1
  475.            BRA.B     1$
  476.  
  477. 2$           MOVEQ.L     #NOITEM,D0
  478. 3$           RTS
  479.  
  480. *************************************************
  481. * FindWindow() - Check if window is still open. *
  482. *                        *
  483. * Input:                    *
  484. *   none                    *
  485. * Output:                    *
  486. *   return  - TRUE if window is open.        *
  487. *************************************************
  488. @FindWindow:   MOVE.L    D2,-(SP)
  489.            MOVE.L    A6,-(SP)
  490.  
  491. * ------------ Lock = LockIBase(0)
  492.            MOVEQ.L     #0,D0
  493.            MOVEA.L     _IntuitionBase(A4),A6
  494.            JSR     _LVOLockIBase(A6)
  495.  
  496. * ------------ TestScreen = IntuitionBase->FirstScreen
  497.            MOVEA.L     ib_FirstScreen(A6),A0
  498.  
  499. * ------------ TestScreen == NULL ?
  500. 1$           MOVE.L     A0,D1
  501.            BEQ.B     5$
  502.  
  503. * ------------ TestScreen == Screen ?
  504.            CMPA.L     _Screen(A4),A0
  505.            BNE.B     4$
  506.  
  507. * ------------ TestWindow = TestScreen->FirstWindow
  508.            MOVEA.L     sc_FirstWindow(A0),A1
  509.  
  510. * ------------ TestWindow == NULL ?
  511. 2$           MOVE.L     A1,D1
  512.            BEQ.B     5$
  513.  
  514. * ------------ TestWindow == ActiveWindow ?
  515.            CMPA.L     _ActiveWindow(A4),A1
  516.            BNE.B     3$
  517.  
  518.            MOVEQ.L     #TRUE,D2
  519.            BRA.B     6$
  520.  
  521. * ------------ TestWindow = TestWindow->NextWindow
  522. 3$           MOVEA.L     (A1),A1
  523.            BRA.B     2$
  524.  
  525. * ------------ TestScreen = TestScreen->NextScreen
  526. 4$           MOVEA.L     (A0),A0
  527.            BRA.B     1$
  528.  
  529. 5$           MOVEQ.L     #FALSE,D2
  530.  
  531. * ------------ UnlockIBase(Lock)
  532. 6$           MOVEA.L     D0,A0
  533.            JSR     _LVOUnlockIBase(A6)
  534.  
  535.            MOVE.L     D2,D0
  536.  
  537.            MOVEA.L     (SP)+,A6
  538.            MOVE.L     (SP)+,D2
  539.            RTS
  540.  
  541. ***************************************************
  542. * MouseInWindow(Window) - Is mouse inside window. *
  543. *                          *
  544. * Input:                      *
  545. *   Window    - Window to check.          *
  546. * Output:                      *
  547. *   return    - TRUE if mouse inside.          *
  548. ***************************************************
  549. @MouseInWindow:
  550.            MOVEQ.L     #FALSE,D0
  551.  
  552. * ------------ MouseX > Window->LeftEdge ?
  553.            MOVE.W     _MouseX(A4),D1
  554.            CMP.W     wwd_LeftEdge(A0),D1
  555.            BLE.B     1$
  556.  
  557. * ------------ MouseX < Window->RightEdge ?
  558.            CMP.W     wwd_RightEdge(A0),D1
  559.            BGE.B     1$
  560.  
  561. * ------------ MouseY > Window->TopEdge ?
  562.            MOVE.W     _MouseY(A4),D1
  563.            CMP.W     wwd_TopEdge(A0),D1
  564.            BLE.B     1$
  565.  
  566. * ------------ MouseY < Window->Bottom ?
  567.            CMP.W     wwd_Bottom(A0),D1
  568.            BGE.B     1$
  569.  
  570.            MOVEQ.L     #TRUE,D0
  571. 1$           RTS
  572. ****************************************************************
  573. * FindMouseItem(Window) - Check if mouse inside an item.       *
  574. *                                   *
  575. * Input:                               *
  576. *   ItemWindow - Window with items                   *
  577. * Output:                               *
  578. *   return - Pointer to item under the mousepointer (or NULL). *
  579. ****************************************************************
  580. @FindMouseItem:
  581.            MOVE.W     D2,-(SP)
  582.  
  583. * ------------ MouseWinX = MouseX + Window->LeftValue
  584.            MOVE.W     _MouseX(A4),D1
  585.            ADD.W     wwd_LeftValue(A0),D1
  586.  
  587. * ------------ MouseWinY = MouseY + Window->TopValue
  588.            MOVE.W     _MouseY(A4),D2
  589.            ADD.W     wwd_TopValue(A0),D2
  590.  
  591. * ------------ Item = Window->Items
  592.            MOVEA.L     wwd_Items(A0),A0
  593.  
  594. * ------------ MouseWinY >= Item->TopEdge ?
  595. 1$           MOVE.W     mi_TopEdge(A0),D0
  596.            CMP.W     D0,D2
  597.            BLT.B     2$
  598.  
  599. * ------------ MouseWinY <= Item->TopEdge + Item->Height ?
  600.            ADD.W     mi_Height(A0),D0
  601.            CMP.W     D0,D2
  602.            BGT.B     2$
  603.  
  604. * ------------ MouseWinX >= Item->LeftEdge ?
  605.            MOVE.W     mi_LeftEdge(A0),D0
  606.            CMP.W     D0,D1
  607.            BLT.B     2$
  608.  
  609. * ------------ MouseWinX <= Item->LeftEdge + Item->Width ?
  610.            ADD.W     mi_Width(A0),D0
  611.            CMP.W     D0,D1
  612.            BGT.B     2$
  613.  
  614. * ------------ return Item.
  615.            MOVE.L     A0,D0
  616.            BRA.B     3$
  617.  
  618. * ------------ Try next item.
  619. 2$           MOVEA.L     (A0),A0
  620.            MOVE.L     A0,D0
  621.            BNE.B     1$
  622.  
  623. 3$           MOVE.W    (SP)+,D2
  624.            RTS
  625.  
  626. *********************************************************
  627. * HighLightCurrItemBehind(Mode) - Highlight currentitem *
  628. *                   behind subwindow.    *
  629. * Input:                        *
  630. *   Mode.W - HIGHLIGHTON or HIGHLIGHTOFF.        *
  631. * Output:                        *
  632. *   none                        *
  633. * Functions:                        *
  634. *   SwapBits, HighLightItem                *
  635. *********************************************************
  636. @HighLightCurrItemBehind:
  637.            MOVE.W     D0,-(SP)
  638.  
  639. * ------------ SwapBits(SubWindow)
  640.            LEA     _SubWindow(A4),A0
  641.            JSR     @SwapBits(PC)
  642.  
  643. * ------------ HighLightItem(&ItemWindow,Mode)
  644.            MOVE.W     (SP)+,D0
  645.            LEA     _ItemWindow(A4),A0
  646.            JSR     @HighLightItem(PC)
  647.  
  648. * ------------ SwapBits(SubWindow)
  649.            LEA     _SubWindow(A4),A0
  650.            JSR     @SwapBits(PC)
  651.  
  652.            RTS
  653.  
  654. ******************************************
  655. * OpenMenuWindow(StartPos)               *
  656. *                     *
  657. * Input:                 *
  658. *   StartPos  - Position from menutop.     *
  659. * Output:                 *
  660. *   return    - TRUE if window opened.     *
  661. * Functions:                 *
  662. *   Mystrlen, BuildBitMap, DrawAllMenues *
  663. ******************************************
  664. @OpenMenuWindow:
  665.            MOVEM.L     D4-D7/A3/A5,-(SP)
  666.            MOVE.W     D0,D7
  667.  
  668. * ------------ Sort menues after their LeftEdge
  669.            JSR     @SortMenues(PC)
  670.            TST.L     D0
  671.            BEQ.W     OpenMenuDone
  672.  
  673.            MOVEA.L     _GfxBase(A4),A6
  674.  
  675. * ------------ Just one menu ? (4.0)
  676.            MOVEA.L     _Menues(A4),A3
  677.            TST.L     mu_NextMenu(A3)
  678.            BNE.B     2$            * No
  679.  
  680. * ------------ Single menu name option set ?
  681.            BTST     #SHOWSINGLEMENU,_Options(A4)
  682.            BNE.B     2$            * Yes
  683.  
  684. * ------------ ItemWindow.ItemsEnabled = Menues->Flags & MENUENABLED
  685.            LEA     _ItemWindow(A4),A0
  686.            MOVEQ.L     #MENUENABLED,D0
  687.            AND.W     mu_Flags(A3),D0
  688.            MOVE.W     D0,wwd_ItemsEnabled(A0)
  689.  
  690. * ------------ ItemWindow.Items = Menues->FirstItem
  691.            MOVE.L     mu_FirstItem(A3),wwd_Items(A0)
  692.  
  693. * ------------ FindItemWinSize(ItemWindow, ITEMWINDOW)
  694.            MOVEQ.L     #ITEMWINDOW,D0
  695.            JSR     @FindItemWinSize(PC)
  696.  
  697.            TST.L     D0
  698.            BEQ.S     2$          * No items
  699.  
  700. * ------------ MenuWidth = Size.Right - Size.Left
  701.            MOVE.W     _Size+ws_Right(A4),D6
  702.            SUB.W     _Size+ws_Left(A4),D6
  703.  
  704. * ------------ Length = TextLength(&Rp,MenuPtr->MenuName,Mystrlen(MenuPtr->MenuName))
  705.            MOVEA.L     mu_MenuName(A3),A0
  706.            JSR     @Mystrlen(PC)
  707.            LEA     _Rp(A4),A1
  708.            MOVEA.L     mu_MenuName(A3),A0
  709.            JSR     _LVOTextLength(A6)
  710.  
  711. * ------------ Length <= MenuWidth ?
  712.            CMP.W     D0,D6
  713.            BGE.B     1$           * Yes
  714.  
  715. * ------------ Size.Right += Length - MenuWidth
  716.            MOVE.W     _Size+ws_Right(A4),D1
  717.            ADD.W     D0,D1
  718.            SUB.W     D6,D1
  719.            MOVE.W     D1,_Size+ws_Right(A4)
  720.  
  721. * ------------ MenuWidth = Length
  722.            MOVE.W     D0,D6
  723.  
  724. * ------------ MenuWidth += 2 * VBORDERSIZE
  725. 1$           ADDQ.W     #2*VBORDERSIZE,D6
  726.  
  727. * ------------ MenuHeight = Size.Bottom - Size.Top + 2 * HBORDERSIZE + MenuFontSize
  728.            MOVE.W     _Size+ws_Bottom(A4),D5
  729.            SUB.W     _Size+ws_Top(A4),D5
  730.            ADDQ.W     #2*HBORDERSIZE,D5
  731.            ADD.W     _MenuFontSize(A4),D5
  732.  
  733. * ------------ MenuTop = 0
  734.            MOVEQ.L     #0,D7
  735.  
  736. * ------------ Window = ItemWindow
  737.            LEA     _ItemWindow(A4),A3
  738.            BRA.B     PosLeft
  739.  
  740. * ------------ MenuWidth = 0
  741. 2$           MOVEQ.L     #0,D6
  742.  
  743. * ------------ MenuHeight = HBORDERSIZE + 1
  744.            MOVEQ.L     #HBORDERSIZE+1,D5
  745.  
  746. ****************************************
  747. * Find width & height of window needed *
  748. ****************************************
  749. ***********************************
  750. * D5 = MenuHeight    A3 = Menues  *
  751. * D6 = MenuWidth     A6 = GfxBase *
  752. * D7 = MenuTop              *
  753. ***********************************
  754. * ------------ Length = TextLength(&Rp,MenuPtr->MenuName,Mystrlen(MenuPtr->MenuName))
  755. 3$           MOVEA.L     mu_MenuName(A3),A0
  756.            JSR     @Mystrlen(PC)
  757.            LEA     _Rp(A4),A1
  758.            MOVEA.L     mu_MenuName(A3),A0
  759.            JSR     _LVOTextLength(A6)
  760.  
  761. * ------------ MenuPtr->Width > Length ?
  762.            MOVE.W     mu_Width(A3),D1
  763.            CMP.W     D0,D1
  764.            BLS.B     4$           * No
  765.  
  766. * ------------ Length = MenuPtr->Width
  767.            MOVE.L     D1,D0
  768.  
  769. * ------------ Length > MenuWidth ?
  770. 4$           CMP.W     D6,D0
  771.            BLS.B     5$           * No
  772.  
  773. * ------------ MenuWidth = Length
  774.            MOVE.W     D0,D6
  775.  
  776. * ------------ MenuHeight += MenuFontSize
  777. 5$           ADD.W     _MenuFontSize(A4),D5
  778.  
  779. * ------------ Check next menu.
  780.            MOVEA.L     (A3),A3
  781.            MOVE.L     A3,D0
  782.            BNE.B     3$
  783.  
  784. * ------------ MenuWidth += (2 * VBORDERSIZE + 1)
  785.            ADDQ.W     #2*VBORDERSIZE,D6
  786.            ADDQ.W     #1,D6
  787.  
  788. * ------------ Window = MenuWindow
  789.            LEA     _MenuWindow(A4),A3
  790.  
  791. ************************************
  792. * Position window on screen (Left) *
  793. ************************************
  794. ***********************************
  795. *             A3 = Window  *
  796. * D5 = MenuHeight    A6 = GfxBase *
  797. * D6 = MenuWidth          *
  798. * D7 = MenuTop              *
  799. ***********************************
  800. * ------------ MenuLeft = Screen->MouseX - MenuWidth / 2
  801. PosLeft:       MOVE.W     D6,D0
  802.            LSR.W     #1,D0
  803.            MOVEA.L     _Screen(A4),A0
  804.            MOVE.W     sc_MouseX(A0),D1
  805.            SUB.W     D0,D1
  806.  
  807. * ------------ MenuLeft < 0 ?
  808.            BGE.B     1$           * No
  809.  
  810. * ------------ MenuLeft = 0
  811.            MOVEQ.L     #0,D1
  812.  
  813. * ------------ MenuLeft > Screen->Width - MenuWidth ?
  814. 1$           MOVE.W     sc_Width(A0),D0
  815.            SUB.W     D6,D0
  816.            CMP.W     D0,D1
  817.            BLE.B     PosTop        * No
  818.  
  819. * ------------ MenuLeft = Screen->Width - MenuWidth
  820.            MOVE.W     D0,D1
  821.  
  822. ***********************************
  823. * Position window on screen (Top) *
  824. ***********************************
  825. ***********************************
  826. * D1 = MenuLeft      A3 = Window  *
  827. * D5 = MenuHeight    A0 = Screen  *
  828. * D6 = MenuWidth     A6 = GfxBase *
  829. * D7 = MenuTop              *
  830. ***********************************
  831. * ------------ MenuTop > MenuHeight ? (Menues has changed)
  832. PosTop:        CMP.W     D5,D7
  833.            BLE.B     1$           * No
  834.  
  835. * ------------ MenuTop = 0
  836.            MOVEQ     #0,D7
  837.  
  838. * ------------ MenuTop    = Screen->MouseY - MenuFontSize/2 - MenuTop
  839. 1$           MOVE.W     _MenuFontSize(A4),D0
  840.            LSR.W     #1,D0
  841.            ADD.W     D0,D7
  842.            SUB.W     sc_MouseY(A0),D7
  843.            NEG.W     D7
  844.  
  845. * ------------ MenuTop < 0 ?
  846.            BPL.B     2$           * No
  847.  
  848. * ------------ MenuTop = 0
  849.            MOVEQ.L     #0,D7
  850.  
  851. * ------------ MenuTop > Screen->Height - MenuHeight ?
  852. 2$           MOVE.W     sc_Height(A0),D0
  853.            SUB.W     D5,D0
  854.            CMP.W     D0,D7
  855.            BLE.B     3$           * No
  856.  
  857. * ------------ MenuTop = Screen->Height - MenuHeight
  858.            MOVE.L     D0,D7
  859.  
  860. * ------------ Window->TopEdge = MenuTop
  861. 3$           MOVE.W     D7,wwd_TopEdge(A3)
  862.  
  863. * ------------ Window->Height = MenuHeight
  864.            MOVE.W     D5,wwd_Height(A3)
  865.  
  866. * ------------ Window->LeftEdge = MenuLeft
  867.            MOVE.W     D1,wwd_LeftEdge(A3)
  868.  
  869. * ------------ Window->Width = MenuWidth;
  870.            MOVE.W     D6,wwd_Width(A3)
  871.  
  872. *******************************
  873. * Open window with right size *
  874. *******************************
  875. * ------------ BuildBitMap(Window)
  876. Open:           MOVEA.L     A3,A0
  877.            JSR     @BuildBitMap(PC)
  878.  
  879. * ------------ Window open ?
  880.            TST.W     D0
  881.            BEQ.B     OpenMenuDone  * No
  882.  
  883.  
  884. * ------------ Window == ITEMWINDOW ?    [ Single menu ]
  885.            LEA     _ItemWindow(A4),A0
  886.            CMPA.L     A0,A3
  887.            BNE.S     1$            * No
  888.  
  889. * ------------ ItemWindow.LeftValue = Size.Left - WindowLeft - VBORDERSIZE
  890.            MOVE.W     _Size+ws_Left(A4),D0
  891.            SUB.W     wwd_LeftEdge(A3),D0
  892.            SUBQ.W     #VBORDERSIZE,D0
  893.            MOVE.W     D0,wwd_LeftValue(A3)
  894.  
  895. * ------------ ItemWindow.TopValue = Size.Top - WindowTop - HBORDERSIZE - MenuFontSize
  896.            MOVE.W     _Size+ws_Top(A4),D0
  897.            SUB.W     wwd_TopEdge(A3),D0
  898.            SUBQ.W     #HBORDERSIZE,D0
  899.            SUB.W     _MenuFontSize(A4),D0
  900.            MOVE.W     D0,wwd_TopValue(A3)
  901.  
  902. * ------------ DrawAllItems(&ItemWindow)
  903.            MOVEA.L     A3,A0
  904.            JSR     @DrawAllItems(PC)
  905.  
  906. * ------------ CurrentMenuNr = 1
  907.            MOVEQ.L     #1,D0
  908.            MOVE.W     D0,_CurrentMenuNr(A4)
  909.  
  910. * ------------ DrawAllMenues(Window)
  911. 1$           MOVEA.L     A3,A0
  912.            JSR     @DrawAllMenues(PC)
  913.  
  914. * ------------ return (TRUE)
  915.            MOVEQ.L     #TRUE,D0
  916.  
  917. OpenMenuDone:  MOVEM.L     (SP)+,D4-D7/A3/A6
  918.            RTS
  919.  
  920. **********************************
  921. * BOOL SortMenues()              *
  922. *                 *
  923. * Input:             *
  924. *   none.             *
  925. * Output:             *
  926. *   TRUE    if everything is ok. *
  927. **********************************
  928. @SortMenues:   MOVEM.L     A2-A3/A5-A6,-(SP)
  929.            MOVEA.L     _IntuitionBase(A4),A6
  930.            MOVEQ.L     #NULL,D1
  931.  
  932. * ------------ SortRemember = NULL
  933.            MOVE.L     D1,_SortRemember(A4)
  934.  
  935. * ------------ MenuSorted.Next = NULL
  936.            MOVE.L     D1,_MenuSorted+ms_Next(A4)
  937.  
  938.            MOVEA.L     _Menues(A4),A5
  939.  
  940. * ------------ SortData = AllocRemember(SortRemember,sizeof(struct MenuSort),0)
  941. 0$           LEA     _SortRemember(A4),A0
  942.            MOVEQ.L     #ms_SIZEOF,D0
  943.            MOVEQ.L     #0,D1
  944.            JSR     _LVOAllocRemember(A6)
  945.            TST.L     D0
  946.            BEQ.B     3$
  947.            MOVE.L     D0,A0
  948.  
  949. * ------------ SortData.MenuPtr = Menues
  950.            MOVE.L     A5,ms_MenuPtr(A0)
  951.  
  952.            MOVE.W     mu_LeftEdge(A5),D1
  953.  
  954. * ------------ TempSort = Sorted
  955.            LEA     _MenuSorted(A4),A3
  956.  
  957. **************************************************
  958. * D1 = LeftEdge for TestMenu  A3 = MenuSorted     *
  959. *                  A5 = TestMenu     *
  960. *                  A6 = IntuitionBase *
  961. **************************************************
  962. 1$           MOVEA.L     (A3),A1        * ms_Next(A3)
  963.            MOVE.L     A1,D0
  964.            BEQ.B     2$
  965.  
  966.            MOVEA.L     ms_MenuPtr(A1),A2
  967.            CMP.W     mu_LeftEdge(A2),D1
  968.            BLE.B     2$
  969.  
  970.            MOVEA.L     A1,A3
  971.            BRA.B     1$
  972.  
  973. 2$           MOVE.L     A1,(A0)        * ms_Next(A0)
  974.            MOVE.L     A0,(A3)        * ms_Next(A3)
  975.  
  976.            MOVEA.L     (A5),A5        * mu_NextMenu
  977.            MOVE.L     A5,D0
  978.            BNE.B     0$
  979.            MOVEQ.L     #TRUE,D0
  980.  
  981. 3$           MOVEM.L     (SP)+,A2-A3/A5-A6
  982.            RTS
  983.  
  984. **************************************************************
  985. * OpenItemWindow(ItemWindow,ParentWindow,TopPos,WindowType)  *
  986. *                                 *
  987. * Input:                             *
  988. *   Window     - Window to open.                 *
  989. *   ParentWindow -                         *
  990. *   TopPos.W     - Top position for new window.          *
  991. *   WindowType.W - ITEMWINDOW or SUBWINDOW             *
  992. * Output:                             *
  993. *   return     - TRUE if OK                     *
  994. * Functions:                             *
  995. *   FindItemWinSize, PosItemWinLeft, PosItemWinTop,         *
  996. *   BuildBitMap, DrawAllItems                     *
  997. **************************************************************
  998. @OpenItemWindow:
  999.            MOVEM.L     D6-D7/A2-A3,-(SP)
  1000.            MOVEA.L     A0,A3
  1001.            MOVEA.L     A1,A2
  1002.            MOVE.W     D0,D7
  1003.            MOVE.W     D1,D6
  1004.  
  1005. * ------------ FindItemWinSize(Window,WindowType)
  1006.            MOVE.W     D6,D0
  1007.            JSR     @FindItemWinSize(PC)
  1008.  
  1009. * ------------ Empty menu ?
  1010.            TST.L     D0
  1011.            BEQ.B     1$
  1012.  
  1013. * ------------ PosItemWinLeft(Window,ParentWindow,WindowType)
  1014.            MOVE.W     D6,D0
  1015.            MOVEA.L     A3,A0
  1016.            MOVEA.L     A2,A1
  1017.            BSR.B     @PosItemWinLeft
  1018.  
  1019. * ------------ PosItemWinTop(Window,TopPos, WindowType)
  1020.            MOVE.W     D7,D0
  1021.            MOVE.W     D6,D1
  1022.            MOVEA.L     A3,A0
  1023.            JSR     @PosItemWinTop(PC)
  1024.  
  1025. * ------------ BuildBitMap(Window)
  1026.            MOVEA.L     A3,A0
  1027.            JSR     @BuildBitMap(PC)
  1028.  
  1029.            TST.W     D0
  1030.            BEQ.B     1$
  1031.  
  1032. * ------------ DrawAllItems(Window)
  1033.            MOVEA.L     A3,A0
  1034.            JSR     @DrawAllItems(PC)
  1035.  
  1036.            MOVEQ.L     #TRUE,D0
  1037.  
  1038. 1$           MOVEM.L     (SP)+,D6-D7/A2-A3
  1039.            RTS
  1040.  
  1041. ******************************************************
  1042. * PosItemWinLeft(Window,ParentWindow,WindowType) *
  1043. * - Position window on screen (left)                 *
  1044. *                             *
  1045. * Input:                         *
  1046. *   Window     - Window to position.             *
  1047. *   ParentWindow - Window to position next to.         *
  1048. *   WindowType.W - ITEMWINDOW or SUBWINDOW.         *
  1049. *                             *
  1050. * Possible positions:                     *
  1051. *   1. At real position (a'la intuition).            *
  1052. *   2. At right side of parent.              *
  1053. *   3. At left side of parent.                 *
  1054. *   4. On the side that covers parent least.         *
  1055. ******************************************************
  1056. @PosItemWinLeft:
  1057.            MOVEM.L     D3-D7/A2,-(SP)
  1058.  
  1059. * ------------ LeftValue = Size.Left - VBORDERSIZE
  1060.            MOVE.W     _Size+ws_Left(A4),D6
  1061.            SUBQ.W     #VBORDERSIZE,D6
  1062.  
  1063. * ------------ WindowWidth = Size.Right - LeftValue + VBORDERSIZE
  1064.            MOVE.W     _Size+ws_Right(A4),D5
  1065.            SUB.W     D6,D5
  1066.            ADDQ.W     #VBORDERSIZE,D5
  1067.  
  1068. * ------------ LeftPos2 = ParentWindow->LeftEdge - WindowWidth + OVERLAP
  1069.            MOVE.W     wwd_LeftEdge(A1),D1
  1070.            MOVE.W     D1,D4
  1071.            SUB.W     D5,D4
  1072.            ADDQ.W     #OVERLAP,D4
  1073.  
  1074. * ------------ MaxLeft = Screen->Width - WindowWidth
  1075.            MOVEA.L     _Screen(A4),A2
  1076.            MOVE.W     sc_Width(A2),D3
  1077.            SUB.W     D5,D3
  1078. **********************************************
  1079. * D0 = WindowType      A0 = Window         *
  1080. * D1 = Parent->LeftEdge   A1 = ParentWindow  *
  1081. * D2 =              A2 = Screen         *
  1082. * D3 = MaxLeft                     *
  1083. * D4 = LeftPos2                  *
  1084. * D5 = WindowWidth                 *
  1085. * D6 = LeftValue                 *
  1086. * D7 = WindowLeft                 *
  1087. **********************************************
  1088. * ------------ WindowType == ITEMWINDOW ?
  1089.            TST.W     D0
  1090.            BEQ.B     1$    * Yes
  1091.  
  1092. * ------------ WindowLeft = ParentWindow->LeftEdge + LeftValue
  1093.            MOVE.W     D1,D7
  1094.            ADD.W     D6,D7
  1095.  
  1096. * ------------ WindowLeft > MaxLeft ?
  1097.            CMP.W     D7,D3
  1098.            BLT.B     1$    * Yes
  1099.  
  1100. * ------------ WindowLeft < 0 ?
  1101.            TST.W     D7
  1102.            BPL.B     2$    * No
  1103.  
  1104. * ------------ WindowLeft = ParentWindow->RightEdge - OVERLAP
  1105. 1$           MOVE.W     wwd_RightEdge(A1),D7
  1106.            SUBQ.W     #OVERLAP,D7
  1107.  
  1108. * ------------ WindowLeft > MaxLeft ?
  1109. 2$           CMP.W     D7,D3
  1110.            BGE.B     4$    * No
  1111.  
  1112. * ------------ LeftPos2 > MaxLeft - WindowLeft ?
  1113.            MOVE.W     D3,D0
  1114.            SUB.W     D7,D0
  1115.            CMP.W     D4,D0
  1116.            BGE.B     3$    * No
  1117.  
  1118. * ------------ WindowLeft = (LeftPos2 > 0) ? LeftPos2 : 0
  1119.            MOVE.W     D4,D7
  1120.            BGT.B     4$
  1121.            MOVEQ.L     #0,D7
  1122.            BRA.B     4$
  1123.  
  1124. * ------------ WindowLeft = MaxLeft
  1125. 3$           MOVE.W     D3,D7
  1126.  
  1127. * ------------ WindowWidth < ParentWindow->LeftEdge + OVERLAP - WindowLeft ?
  1128. 4$           MOVE.W     D1,D0
  1129.            ADDQ.W     #OVERLAP,D0
  1130.            SUB.W     D7,D0
  1131.            CMP.W     D5,D0
  1132.            BLE.B     5$           * No
  1133.  
  1134. * ------------ WindowWidth = ParentWindow->LeftEdge + OVERLAP - WindowLeft
  1135.            MOVE.W     D0,D5
  1136.  
  1137. * ------------ Window->LeftEdge = WindowLeft
  1138. 5$           MOVE.W     D7,wwd_LeftEdge(A0)
  1139.  
  1140. * ------------ Window->LeftValue = LeftValue - WindowLeft
  1141.            SUB.W     D7,D6
  1142.            MOVE.W     D6,wwd_LeftValue(A0)
  1143.  
  1144. * ------------ Window->Width = WindowWidth
  1145.            MOVE.W     D5,wwd_Width(A0)
  1146.  
  1147.            MOVEM.L     (SP)+,D3-D7/A2
  1148.            RTS
  1149.  
  1150. *****************************************************
  1151. * PosItemWinTop(Window,TopPos, WindowType)          *
  1152. * - Position Window on screen (Top).                *
  1153. *                            *
  1154. * Input:                        *
  1155. *   Window     - Window to position. (A0)         *
  1156. *   TopPos.W     -               (D0)         *
  1157. *   WindowType.W - ITEMWINDOW or SUBITEMWINDOW (D1) *
  1158. *****************************************************
  1159. @PosItemWinTop:
  1160.            MOVEM.L     D4-D7,-(SP)
  1161.  
  1162. * ------------ TopValue = Size.Top - HBORDERSIZE
  1163.            MOVE.W     _Size+ws_Top(A4),D6
  1164.            SUBQ.W     #HBORDERSIZE,D6
  1165.  
  1166. * ------------ WindowHeight = Size.Bottom - TopValue + HBORDERSIZE
  1167.            MOVE.W     _Size+ws_Bottom(A4),D4
  1168.            SUB.W     D6,D4
  1169.            ADDQ.W     #HBORDERSIZE,D4
  1170.            MOVEA.L     _Screen(A4),A1
  1171.  
  1172. * ------------ WindowTop = TopPos
  1173.            MOVE.W     D0,D5
  1174.  
  1175. * ------------ WindowType == ITEMWINDOW ?
  1176.            TST.W     D1
  1177.            BNE.B     1$           * No
  1178.  
  1179. * ------------ Center Items ?
  1180.            BTST     #ITEMSCENTERED,_Options(A4)
  1181.            BEQ.B     1$           * No
  1182.  
  1183. * ------------ WindowTop += (MenuFontSize - WindowHeight) / 2
  1184.            MOVE.W     _MenuFontSize(A4),D1
  1185.            SUB.W     D4,D1
  1186.            ASR.W     #1,D1
  1187.            ADD.W     D1,D5
  1188.            BRA.B     2$
  1189.  
  1190. * ------------ WindowTop = TopPos + TopValue
  1191. 1$           ADD.W     D6,D5
  1192.  
  1193. ***********************************
  1194. * D0 = TopPos         A0 = Window  *
  1195. * D4 = WindowHeight  A1 = Screen  *
  1196. * D5 = WindowTop          *
  1197. * D6 = TopValue           *
  1198. ***********************************
  1199. * ------------ WindowTop > Screen->Height - WindowHeight ?
  1200. 2$           MOVE.W     sc_Height(A1),D0
  1201.            SUB.W     D4,D0
  1202.            CMP.W     D5,D0
  1203.            BGE.B     3$           * No
  1204.  
  1205. * ------------ WindowTop = Screen->Height - WindowHeight
  1206.            MOVE.W     D0,D5
  1207.  
  1208. * ------------ WindowTop < 0 ?
  1209. 3$           TST.W     D5
  1210.            BPL.B     4$           * No
  1211.  
  1212. * ------------ WindowTop = 0
  1213.            MOVEQ.L     #0,D5
  1214.  
  1215. * ------------ Window->TopEdge = WindowTop
  1216. 4$           MOVE.W     D5,wwd_TopEdge(A0)
  1217.  
  1218. * ------------ Window->TopValue = TopValue - WindowTop
  1219.            SUB.W     D5,D6
  1220.            MOVE.W     D6,wwd_TopValue(A0)
  1221.  
  1222. * ------------ Window->Height = WindowHeight
  1223.            MOVE.W     D4,wwd_Height(A0)
  1224.  
  1225.            MOVEM.L     (SP)+,D4-D7
  1226.            RTS
  1227.  
  1228. *************************************************************
  1229. *  TellWindow(InputSignals,MenuNum) - Send Fake Menu Event. *
  1230. *         A0        D0                    *
  1231. * Input:                            *
  1232. *   MenuNum -    Menu number to send.                *
  1233. *   InputSignals - InputHandler data for Qualifiers        *
  1234. * Output:                            *
  1235. *   none                            *
  1236. * Functions:                            *
  1237. *   FindWindow                            *
  1238. *************************************************************
  1239. @TellWindow:   MOVE.L    A2,-(SP)
  1240.            MOVE.L    A6,-(SP)
  1241.            LEA     -ie_SIZEOF(SP),SP
  1242.  
  1243. * ------------ MyFakeEvent.ie_Class = IECLASS_MENULIST
  1244.            MOVE.B     #IECLASS_MENULIST,ie_Class(SP)
  1245.  
  1246. * ------------ MyFakeEvent.ie_Code = MenuNumber
  1247.            MOVE.W     D0,ie_Code(SP)
  1248.  
  1249. * ------------ MyFakeEvent.ie_Qualifier = InputSignals.EndQualifier
  1250.            MOVE.W     sd_EndQualifier(A0),ie_Qualifier(SP)
  1251.  
  1252. * ------------ MyFakeEvent.ie_NextEvent = NULL
  1253.            CLR.L     (SP)
  1254.  
  1255. * ------------ MyFakeEvent.ie_EventAddress = NULL
  1256.            CLR.L     ie_EventAddress(SP)
  1257.  
  1258. * ------------ Get current time.
  1259.            LEA     ie_TimeStamp+TV_SECS(SP),A0
  1260.            LEA     ie_TimeStamp+TV_MICRO(SP),A1
  1261.            MOVEA.L     _IntuitionBase(A4),A6
  1262.            JSR     _LVOCurrentTime(A6)
  1263.  
  1264. * ------------ InputReqBlock->io_Command = IND_WRITEEVENT
  1265.            MOVEA.L     _InputReqBlock(A4),A2
  1266.            MOVE.W     #IND_WRITEEVENT,IO_COMMAND(A2)
  1267.  
  1268. * ------------ InputReqBlock->io_Flags     = 0
  1269.            CLR.B     IO_FLAGS(A2)
  1270.  
  1271. * ------------ InputReqBlock->io_Length = sizeof(struct InputEvent)
  1272.            MOVEQ.L     #ie_SIZEOF,D0
  1273.            MOVE.L     D0,IO_LENGTH(A2)
  1274.  
  1275. * ------------ InputReqBlock->io_Data = &MyFakeEvent
  1276.            MOVE.L     SP,IO_DATA(A2)
  1277.  
  1278. * ------------ Be sure the right window will get the message.
  1279.            JSR     @FindWindow(PC)
  1280.            TST.W     D0
  1281.            BEQ.B     1$
  1282.  
  1283.            MOVEA.L     _ActiveWindow(A4),A0
  1284.            JSR     _LVOActivateWindow(A6)
  1285.  
  1286. * ------------ DoIO(InputReqBlock)
  1287.            MOVEA.L     A2,A1
  1288.            MOVEA.L     (A4),A6       * SysBase
  1289.            JSR     _LVODoIO(A6)
  1290.  
  1291. 1$           LEA     ie_SIZEOF(SP),SP
  1292.            MOVEA.L     (SP)+,A6
  1293.            MOVEA.L     (SP)+,A2
  1294.            RTS
  1295.  
  1296. ****************************************
  1297. * DrawAllItems(Window)                 *
  1298. *                       *
  1299. * Input:                   *
  1300. *   Window  - Window to draw into.     *
  1301. *                       *
  1302. * Output:                   *
  1303. *   none                   *
  1304. * Functions:                   *
  1305. *   ClearWindow, DrawMenuItem           *
  1306. ****************************************
  1307. @DrawAllItems: MOVE.L     A2,-(SP)
  1308.            MOVE.L     A3,-(SP)
  1309.  
  1310.            MOVEA.L     A0,A3
  1311.  
  1312. * ------------ Item = Window->Items
  1313.            MOVEA.L     wwd_Items(A3),A2
  1314.  
  1315. * ------------ ClearWindow(Window)
  1316.            BSR.B     @ClearWindow
  1317.  
  1318. * ------------ DrawMenuItem(Window, Item, ITEMFILL)
  1319. 1$           MOVEQ.L     #ITEMFILL,D0
  1320.            MOVEA.L     A3,A0
  1321.            MOVEA.L     A2,A1
  1322.            JSR     @DrawMenuItem(PC)
  1323.  
  1324. * ------------ Item = Item->NextItem
  1325.            MOVEA.L     (A2),A2
  1326.            MOVE.L     A2,D0
  1327.            BNE.B     1$
  1328.  
  1329.            MOVEA.L     (SP)+,A3
  1330.            MOVEA.L     (SP)+,A2
  1331.            RTS
  1332.  
  1333. *********************************
  1334. * ClearWindow(window)           *
  1335. *                *
  1336. * Input:            *
  1337. *   Window   - Window to clear. *
  1338. * Output:            *
  1339. *   none            *
  1340. *********************************
  1341. @ClearWindow:  MOVEM.L     D2-D5/A2-A3/A5-A6,-(SP)
  1342.            MOVEA.L     A0,A3
  1343.  
  1344.            LEA     _Rp(A4),A2
  1345.            MOVEA.L     _ActiveWindow(A4),A5
  1346.            MOVEA.L     _GfxBase(A4),A6
  1347. *********************
  1348. * A2 = Rp        *
  1349. * A3 = Window        *
  1350. * A5 = ActiveWindow *
  1351. * A6 = GfxBase        *
  1352. *********************
  1353. * ------------ SetDrMd(Rp, JAM1)
  1354.            MOVEA.L     A2,A1
  1355.            MOVEQ.L     #RP_JAM1,D0
  1356.            JSR     _LVOSetDrMd(A6)
  1357.  
  1358. * ------------ SetAPen(Rp,ActiveWindow->DetailPen)
  1359.            MOVEA.L     A2,A1
  1360.            MOVEQ.L     #0,D0
  1361.            MOVE.B     wd_DetailPen(A5),D0
  1362.            JSR     _LVOSetAPen(A6)
  1363.  
  1364. * ------------ Left = Window->LeftEdge
  1365.            MOVEQ.L     #0,D0
  1366.            MOVE.W     wwd_LeftEdge(A3),D0
  1367.  
  1368. * ------------ Top = Window->TopEdge
  1369.            MOVEQ.L     #0,D1
  1370.            MOVE.W     wwd_TopEdge(A3),D1
  1371.  
  1372. * ------------ Right = Window->RightEdge
  1373.            MOVEQ.L     #0,D2
  1374.            MOVE.W     wwd_RightEdge(A3),D2
  1375.  
  1376. * ------------ Bottom = Window->Bottom
  1377.            MOVEQ.L     #0,D3
  1378.            MOVE.W     wwd_Bottom(A3),D3
  1379.  
  1380. * ------------ DrawRect(Left, Top, Right, Bottom)
  1381.            MOVEA.L     A2,A1
  1382.            JSR     @DrawRect(PC)
  1383.  
  1384. * ------------ Save Left & Top.
  1385.            MOVE.L     D0,D4
  1386.            MOVE.L     D1,D5
  1387.  
  1388. * ------------ SetAPen(Rp,ActiveWindow->BlockPen)
  1389.            MOVEA.L     A2,A1
  1390.            MOVEQ.L     #0,D0
  1391.            MOVE.B     wd_BlockPen(A5),D0
  1392.            JSR     _LVOSetAPen(A6)
  1393.  
  1394. * ------------ RectFill(Left, Top, Right, Bottom)
  1395.            MOVEA.L     A2,A1
  1396.            MOVE.L     D4,D0
  1397.            MOVE.L     D5,D1
  1398.            JSR     _LVORectFill(A6)
  1399.  
  1400.            MOVEM.L     (SP)+,D2-D5/A2-A3/A5-A6
  1401.            RTS
  1402.  
  1403. *******************************
  1404. * CloseSubWindow()            *
  1405. * CloseItemWindow()           *
  1406. * CloseMenuWindow()           *
  1407. *                  *
  1408. * Input:              *
  1409. *   none              *
  1410. * Output:              *
  1411. *   none              *
  1412. * Functions:              *
  1413. *   SwapBits, RemoveBitMap    *
  1414. *******************************
  1415. @CloseSubWindow:
  1416.            LEA     _SubWindow(A4),A0
  1417.            TST.W     (A0)          * wwd_BitMapOK
  1418.            BEQ.B     CloseQuit
  1419.  
  1420.            MOVEA.L     wwd_Current(A0),A1
  1421.            MOVE.L     A1,D0
  1422.            BEQ.B     1$
  1423.            BCLR     #HIGHITEMBIT,mi_Flags(A1)
  1424.  
  1425. 1$           MOVEA.L     _ItemWindow+wwd_Current(A4),A1   * This must be something
  1426.            BCLR     #ISDRAWNBIT,mi_Flags(A1)
  1427.            BRA.B     Close
  1428.  
  1429. @CloseItemWindow:
  1430.            LEA     _ItemWindow(A4),A0
  1431.            TST.W     (A0)          * wwd_BitMapOK
  1432.            BEQ.B     CloseQuit
  1433.  
  1434.            MOVEA.L     wwd_Current(A0),A1
  1435.            MOVE.L     A1,D0
  1436.            BEQ.B     1$
  1437.            BCLR     #HIGHITEMBIT,mi_Flags(A1)
  1438.  
  1439. 1$           MOVEA.L     _MenuWindow+wwd_Current(A4),A1
  1440.            BCLR     #MIDRAWNBIT,mu_Flags(A1)
  1441.            BRA.B     Close
  1442.  
  1443. @CloseMenuWindow:
  1444.            LEA     _MenuWindow(A4),A0
  1445.  
  1446. Close:           MOVE.L     A0,-(SP)
  1447.  
  1448. * ------------ Remove window from screen.
  1449.            JSR     @SwapBits(PC)
  1450.  
  1451. * ------------ Remove all bitplanes.
  1452.            MOVEA.L     (SP)+,A0
  1453.            JSR     @RemoveBitMap(PC)
  1454.  
  1455. CloseQuit:     RTS
  1456.  
  1457.  
  1458. ****************************************
  1459. * BuildBitMap(Window)  - OpenWindow    *
  1460. *                       *
  1461. * Input:                   *
  1462. *   Window    - Window to open.        *
  1463. * Output:                   *
  1464. *   return    - TRUE if window opened. *
  1465. ****************************************
  1466.  
  1467. @BuildBitMap:  MOVEM.L     D2-D5/A2-A3/A6,-(SP)
  1468.            MOVEA.L     A0,A3
  1469.  
  1470. * ------------ WindowWidth = Window->Width
  1471.            MOVE.W     wwd_Width(A3),D3
  1472.            EXT.L     D3
  1473.  
  1474. * ------------ WindowHeight = Window->Height
  1475.            MOVE.W     wwd_Height(A3),D2
  1476.            EXT.L     D2
  1477.  
  1478.            MOVEA.L     _Screen(A4),A0
  1479.  
  1480. **************************************
  1481. * D2 = WindowHeight     A0 = Screen *
  1482. * D3 = WindowWidth     A3 = Window *
  1483. **************************************
  1484.  
  1485. * ------------ Is window to big for screen ?
  1486. * ------------ WindowWidth > Screen->Width
  1487.            CMP.W     sc_Width(A0),D3
  1488.            BGT.B     Fail           * Yes
  1489.  
  1490. * ------------ WindowHeight > Screen->Height
  1491.            CMP.W     sc_Height(A0),D2
  1492.            BGT.B     Fail           * Yes
  1493.  
  1494. * ------------ Window->RightEdge = Window->LeftEdge + WindowWidth  - 1
  1495.            MOVE.L     D3,D0
  1496.            ADD.W     wwd_LeftEdge(A3),D0
  1497.            SUBQ.L     #1,D0
  1498.            MOVE.W     D0,wwd_RightEdge(A3)
  1499.  
  1500. * ------------ Window->Bottom     = Window->TopEdge  + WindowHeight - 1
  1501.            MOVE.L     D2,D0
  1502.            ADD.W     wwd_TopEdge(A3),D0
  1503.            SUBQ.L     #1,D0
  1504.            MOVE.W     D0,wwd_Bottom(A3)
  1505.  
  1506. * ------------ Depth = Screen->BitMap.Depth
  1507.            MOVEQ.L     #0,D5
  1508.            MOVE.B     sc_BitMap+bm_Depth(A0),D5
  1509.  
  1510.            MOVEA.L     _GfxBase(A4),A6
  1511.  
  1512. ***************************************
  1513. * D2 = WindowHeight     A0 = Screen  *
  1514. * D3 = WindowWidth     A3 = Window  *
  1515. * D5 = Depth         A6 = GfxBase *
  1516. ***************************************
  1517.  
  1518. * ------------ InitBitMap(&Window->Bm,Depth,WindowWidth,WindowHeight)
  1519.            LEA     wwd_Bm(A3),A0
  1520.            MOVE.L     D5,D0
  1521.            MOVE.L     D3,D1
  1522.            JSR     _LVOInitBitMap(A6)
  1523.  
  1524. * ------------ Window->BitMapOk = TRUE
  1525.            MOVE.W     #TRUE,(A3)
  1526.  
  1527. * ------------ Counter = 0
  1528.            MOVEQ.L     #0,D4
  1529.  
  1530. * ------------ Plane = &Window->Bm.Planes[0]
  1531.            LEA     wwd_Bm+bm_Planes(A3),A2
  1532.  
  1533. ***************************************
  1534. * D2 = WindowHeight     A2 = Planen  *
  1535. * D3 = WindowWidth     A3 = Window  *
  1536. * D4 = Counter         A6 = GfxBase *
  1537. * D5 = Depth                  *
  1538. ***************************************
  1539.  
  1540. * ------------ More planes to allocate ?
  1541. BuildNextPl:   CMP.W     D4,D5
  1542.            BEQ.B     AllRastersOK
  1543.            ADDQ.W     #1,D4
  1544.  
  1545. * ------------ Plane++ = AllocRaster(WindowWidth,WindowHeight)
  1546.            MOVE.L     D3,D0
  1547.            MOVE.L     D2,D1
  1548.            JSR     _LVOAllocRaster(A6)
  1549.            MOVE.L     D0,(A2)+
  1550.  
  1551. * ------------ Out of ChipRam ?
  1552.            BNE.B     BuildNextPl   * No
  1553.  
  1554. * ------------ RemoveBitMap(Window)
  1555.            MOVEA.L     A3,A0
  1556.            BSR.B     @RemoveBitMap
  1557.  
  1558. * ------------ return FALSE
  1559. Fail:           MOVEQ.L     #FALSE,D0
  1560.            BRA.B     BuildDone
  1561.  
  1562. * ------------ Make window visible.
  1563. AllRastersOK:  MOVEA.L     A3,A0
  1564.            BSR.B     @SwapBits
  1565.  
  1566. * ------------ ClearWindow(Window)
  1567.            MOVEA.L     A3,A0
  1568.            JSR     @ClearWindow(PC)
  1569.  
  1570. * ------------ return TRUE
  1571.            MOVEQ.L     #TRUE,D0
  1572.  
  1573. BuildDone:     MOVEM.L     (SP)+,D2-D5/A2-A3/A6
  1574.            RTS
  1575.  
  1576. ****************************************************************************
  1577. * RemoveBitMap(Window) - Remove allocated rasters in the BitMap structure. *
  1578. *                                       *
  1579. * Input:                                   *
  1580. *   Window   - Window with bitmap.                       *
  1581. * Output:                                   *
  1582. *   none                                   *
  1583. ****************************************************************************
  1584. @RemoveBitMap: MOVEM.L     D4-D7/A2/A6,-(SP)
  1585.  
  1586. * ------------ Anything to remove ?
  1587.            TST.W     (A0)          * BitMapOK
  1588.            BEQ.B     RemoveDone
  1589.            CLR.W     (A0)          * BitMapOK
  1590.  
  1591. * ------------ Remove all allocated rasters.
  1592.            MOVEQ.L     #0,D7
  1593.            LEA     wwd_Bm(A0),A2
  1594.            MOVE.B     bm_Depth(A2),D7
  1595.  
  1596.            MOVE.W     wwd_Width(A0),D6
  1597.            EXT.L     D6
  1598.  
  1599.            MOVE.W     wwd_Height(A0),D5
  1600.            EXT.L     D5
  1601.  
  1602.            ADDQ.L     #bm_Planes,A2
  1603.  
  1604.            MOVEA.L     _GfxBase(A4),A6
  1605.  
  1606. * ------------ Counter = 0
  1607.            MOVEQ.L     #0,D4
  1608. *************************************
  1609. * D4 = Counter           A2 = Planes  *
  1610. * D5 = WindowHeight    A0 = Window  *
  1611. * D6 = WindowWidth     A6 = GfxBase *
  1612. * D7 = Depth                *
  1613. *************************************
  1614. RemoveNextPl:  CMP.W     D4,D7
  1615.            BEQ.B     RemoveDone
  1616.            ADDQ.W     #1,D4
  1617.  
  1618. * ------------ This raster allocated ?
  1619.            MOVEA.L     (A2)+,A0
  1620.            MOVE.L     A0,D0
  1621.            BEQ.B     RemoveDone
  1622.  
  1623. * ------------ FreeRaster(Planes++,Width,Height);
  1624.  
  1625.            MOVE.L     D6,D0
  1626.            MOVE.L     D5,D1
  1627.            JSR     _LVOFreeRaster(A6)
  1628.            BRA.B     RemoveNextPl
  1629.  
  1630. RemoveDone:    MOVEM.L     (SP)+,D4-D7/A2/A6
  1631.            RTS
  1632.  
  1633. *****************************************************************************
  1634. * SwapBits(Window) - Works like SwapBitsRastPortClipRect() without bugs :-) *
  1635. *                                        *
  1636. *****************************************************************************
  1637. ALLPLANES      EQU     -1
  1638. B_XOR_C        EQU     ABNC+ANBC
  1639.  
  1640. * ------------ Check to see that window is open
  1641. @SwapBits:     TST.W      (A0)
  1642.            BEQ.B      NoWindow
  1643.  
  1644.            MOVEM.L      D2-D7/A2/A6,-(SP)
  1645.  
  1646. * ------------ SrcX
  1647.            MOVEQ.L      #0,D0
  1648.            MOVE.W      wwd_LeftEdge(A0),D0
  1649.  
  1650. * ------------ SrcY
  1651.            MOVEQ.L      #0,D1
  1652.            MOVE.W      wwd_TopEdge(A0),D1
  1653.  
  1654. * ------------ SizeX
  1655.            MOVEQ.L      #0,D4
  1656.            MOVE.W      wwd_Width(A0),D4
  1657.  
  1658. * ------------ SizeY
  1659.            MOVEQ.L      #0,D5
  1660.            MOVE.W      wwd_Height(A0),D5
  1661.  
  1662. * ------------ MinTerm
  1663.            MOVEQ.L      #B_XOR_C,D6
  1664.  
  1665. * ------------ Mask
  1666.            MOVEQ.L      #ALLPLANES,D7
  1667.  
  1668. * ------------ TempA = NULL
  1669.            SUB.L      A2,A2
  1670.  
  1671.            MOVE.L      _GfxBase(A4),A6
  1672.  
  1673. * ------------ Off-screen bitmap
  1674.            LEA      wwd_Bm(A0),A1
  1675.  
  1676. * ------------ On-screen bitmap
  1677.            MOVE.L      _Rp+rp_BitMap(A4),A0
  1678.  
  1679. * ------------ DestX = 0
  1680.            MOVEQ.L      #0,D2
  1681.  
  1682. * ------------ DestY = 0
  1683.            MOVEQ.L      #0,D3
  1684.  
  1685. * ------------ OffScreen = OffScreen XOR OnScreen
  1686.            BSR.B      Swap
  1687. * ------------ OnScreen = OnScreen XOR OffScreen  (= OffScreen)
  1688.            BSR.B      Swap
  1689. * ------------ OffScreen = OffScreen XOR OnScreen  (= OnScreen)
  1690.            BSR.B      Swap
  1691.  
  1692.            MOVEM.L      (SP)+,D2-D7/A2/A6
  1693. NoWindow:      RTS
  1694.  
  1695.  
  1696. Swap:           MOVEM.L      D0/D1/A0/A1,-(SP)
  1697.            JSR      _LVOBltBitMap(A6)
  1698.            MOVEM.L      (SP)+,D0/D1/A0/A1
  1699.  
  1700.            EXG.L      A0,A1
  1701.            EXG.L      D0,D2
  1702.            EXG.L      D1,D3
  1703.  
  1704.            RTS
  1705.  
  1706. ********************************************
  1707. * FindItemWinSize(Window,WindowType)       *
  1708. *                       *
  1709. * Find with and hight needed for all items *
  1710. ********************************************
  1711. @FindItemWinSize:
  1712.            MOVE.L    A2,-(SP)
  1713.            MOVE.L    D2,-(SP)
  1714.  
  1715. * ------------ SizeOk = FALSE
  1716.            MOVEQ.L    #FALSE,D2
  1717.  
  1718. * ------------ Item = Window->Items
  1719.            MOVEA.L     wwd_Items(A0),A2
  1720.  
  1721. * ------------ Size.Left  = WORD_MAX
  1722.            MOVE.W     #WORD_MAX,_Size+ws_Left(A4)
  1723.  
  1724. * ------------ Size.Top   = WindowType (ITEMWINDOW -> TopPos >= 0), SUBWINDOW -> no limit */
  1725.            MOVE.W     D0,_Size+ws_Top(A4)
  1726.  
  1727. * ------------ Size.Right = Size.Bottom = WORD_MIN
  1728.            MOVE.W     #WORD_MIN,D0
  1729.            MOVE.W     D0,_Size+ws_Right(A4)
  1730.            MOVE.W     D0,_Size+ws_Bottom(A4)
  1731.  
  1732. * ------------ SizeOk |= CheckItemSize(Item,Item->ItemFill)
  1733. 1$           MOVEA.L     A2,A0
  1734.            MOVEA.L     mi_ItemFill(A0),A1
  1735.            BSR.B     @CheckItemSize
  1736.            OR.L     D0,D2
  1737.  
  1738. * ------------ Item->Flags & HIGHFLAGS == HIGHIMAGE ?
  1739.            MOVE.W     #HIGHFLAGS,D0
  1740.            AND.W     mi_Flags(A2),D0
  1741.            BNE.B     2$
  1742.  
  1743. * ------------ SizeOk |= CheckItemSize(Item,Item->SelectFill)
  1744.            MOVEA.L     A2,A0
  1745.            MOVEA.L     mi_SelectFill(A0),A1
  1746.            BSR.B     @CheckItemSize
  1747.            OR.L     D0,D2
  1748.  
  1749. * ------------ Check next item.
  1750. 2$           MOVEA.L     (A2),A2
  1751.            MOVE.L     A2,D0
  1752.            BNE.B     1$
  1753.  
  1754. * ------------ return SizeOK
  1755.            MOVE.L     D2,D0
  1756.  
  1757.            MOVE.L     (SP)+,D2
  1758.            MOVE.L     (SP)+,A2
  1759.            RTS
  1760.  
  1761. *********************************************************
  1762. * CheckItemSize(Item,Contents) -                        *
  1763. *  find the size needed to include Item in window.    *
  1764. *                            *
  1765. * Input:                        *
  1766. *   Item      (A0)  Item to check.                      *
  1767. *   Contents  (A1)  What to fill (ItemFill/SelectFill). *
  1768. * Output:                        *
  1769. *   Size        New size of window            *
  1770. *   return        TRUE if anything is found.        *
  1771. *********************************************************
  1772. @CheckItemSize:
  1773. * ------------ Anything to check ?
  1774.            MOVE.L      A1,D0
  1775.            BNE.B      1$              * Yes
  1776.            RTS
  1777.  
  1778. 1$           MOVEM.L      D2-D7/A2-A3/A5-A6,-(SP)
  1779.  
  1780.            MOVEA.L      A0,A2           * A2 = Item to check
  1781.            MOVEA.L      A1,A5           * A5 = What to check
  1782.            LEA      _Size(A4),A3        * A3 = SizeSoFar
  1783.  
  1784. * ------------ ImTxLeft = ItemLeft = Item->LeftEdge
  1785. Check:           MOVE.W      mi_LeftEdge(A2),D3
  1786.            MOVE.W      D3,D7
  1787.  
  1788. * ------------ ImTxTop = ItemTop = Item->TopEdge
  1789.            MOVE.W      mi_TopEdge(A2),D2
  1790.            MOVE.W      D2,D6
  1791.  
  1792. * ------------ ITEMTEXT or ITEMIMAGE ?
  1793.            MOVEQ.L      #ITEMTEXT,D0
  1794.            AND.W      mi_Flags(A2),D0
  1795.            BEQ.B      ItemImage
  1796.  
  1797. * ------------ Add IText position to left and top.
  1798. * ------------ ImTxLeft += IText.LeftEdge
  1799.            ADD.W      it_LeftEdge(A5),D7
  1800.  
  1801. * ------------ ImTxTop += IText.TopEdge
  1802.            ADD.W      it_TopEdge(A5),D6
  1803.  
  1804. * ------------ ImTxRight = ImTxLeft
  1805.            MOVE.W      D7,D5
  1806.  
  1807. * ------------ ImTxBottom = ImTxTop
  1808.            MOVE.W      D6,D4
  1809.  
  1810. * ------------ What font to use ?
  1811.            MOVE.L      it_ITextFont(A5),D0
  1812.            BEQ.B      DefaultFont
  1813.  
  1814. * ------------ Add height and length of string.
  1815. * ------------ ImTxBottom += IText.ITextFont.YSize
  1816.            MOVEA.L      D0,A0
  1817.            ADD.W      ta_YSize(A0),D4
  1818.  
  1819. * ------------ ImTxRight += IntuiTextLength(IText)
  1820.            MOVEA.L      A5,A0
  1821.            MOVEA.L      _IntuitionBase(A4),A6
  1822.            JSR      _LVOIntuiTextLength(A6)
  1823.  
  1824.            BRA.B      NextText
  1825.  
  1826. * ------------ Add hight and length of string with default font.
  1827. * ------------ ImTxBottom += Rp.TxHeight
  1828. DefaultFont:   ADD.W      _Rp+rp_TxHeight(A4),D4
  1829.  
  1830. * ------------ ItemTextRight += TextLength(Rp,IText,strlen(IText))
  1831.            MOVEA.L      it_IText(A5),A0
  1832.            JSR      @Mystrlen(PC)
  1833.            LEA      _Rp(A4),A1
  1834.            MOVEA.L      it_IText(A5),A0
  1835.            MOVEA.L      _GfxBase(A4),A6
  1836.            JSR      _LVOTextLength(A6)
  1837.  
  1838. NextText:      ADD.W      D0,D5
  1839.  
  1840. * ------------ Move to next text.
  1841.            MOVEA.L      it_NextText(A5),A5
  1842.            BRA.B      CheckLeft
  1843.  
  1844. * ------------ ImTxLeft += Image.LeftEdge
  1845. ItemImage:     ADD.W      (A5),D7
  1846.  
  1847. * ------------ ImTxTop += Image.TopEdge
  1848.            ADD.W      ig_TopEdge(A5),D6
  1849.  
  1850. * ------------ ImTxRight = ImTxLeft + Image.Width
  1851.            MOVE.W      D7,D5
  1852.            ADD.W      ig_Width(A5),D5
  1853.  
  1854. * ------------ ImTxBottom = ImTxTop + Image.Height
  1855.            MOVE.W      D6,D4
  1856.            ADD.W      ig_Height(A5),D4
  1857.  
  1858. * ------------ Move to next image
  1859.            MOVE.L      ig_NextImage(A5),A5
  1860.  
  1861. * ------------ Compare with size in SizeSoFar
  1862. * ------------ ItemLeft = Min(ImTxLeft, ItemLeft)
  1863. CheckLeft:     CMP.W      D7,D3
  1864.            BGE.B      1$
  1865.            MOVE.W      D3,D7
  1866.  
  1867. * ------------ SizeSoFar.Left = Min(SizeSoFar.Left, ItemLeft)
  1868. 1$:           CMP.W      (A3),D7
  1869.            BGE.B      CheckRight
  1870.            MOVE.W      D7,(A3)
  1871.  
  1872. * ------------ ItemRight = Max(ItemLeft + Item.Width, ImTxRight)
  1873. CheckRight:    ADD.W      mi_Width(A2),D3
  1874.            CMP.W      D5,D3
  1875.            BLE.B      1$
  1876.            MOVE.W      D3,D5
  1877.  
  1878. * ------------ Item has sub-item ?
  1879. 1$:           TST.L      mi_SubItem(A2)
  1880.            BEQ.B      2$               * No
  1881.  
  1882. * ------------ Sub-item pointer enabled ?
  1883.            BTST      #SUBITEMPOINTER,_Options(A4)
  1884.            BEQ.B      2$               * No
  1885.  
  1886. * ------------ Make room for pointer
  1887. * ------------ ItemRight += (ScreenType & HIRESSCREEN) ? 10 : 6
  1888.            ADDQ.W      #6,D5
  1889.            TST.W      _ScreenType(A4)
  1890.            BNE.B      2$               * LORES
  1891.            ADDQ.W      #4,D5
  1892.  
  1893. * ------------ SizeSoFar.Right = Max(SizeSoFar.Right, ItemRight)
  1894. 2$:           CMP.W      ws_Right(A3),D5
  1895.            BLE.B      CheckTop
  1896.            MOVE.W      D5,ws_Right(A3)
  1897.  
  1898. * ------------ ItemTop = Min(ItemTop, ImTxTop).
  1899. CheckTop:      CMP.W      D6,D2
  1900.            BGE.B      1$
  1901.            MOVE.W      D2,D6
  1902.  
  1903. * ------------ SizeSoFar.Top = Min(SizeSoFar.Top, ItemTop)
  1904. 1$:           CMP.W      ws_Top(A3),D6
  1905.            BGE.B      CheckBottom
  1906.            MOVE.W      D6,ws_Top(A3)
  1907.  
  1908. * ------------ ItemBottom = Max(ItemLeft + Item.Height, ImTxBottom)
  1909. CheckBottom:   ADD.W      mi_Height(A2),D2
  1910.            CMP.W      D4,D2
  1911.            BLE.B      1$
  1912.            MOVE.W      D2,D4
  1913.  
  1914. * ------------ SizeSoFar.Bottom = Max(SizeSoFar.Bottom, ItemBottom)
  1915. 1$:           CMP.W      ws_Bottom(A3),D4
  1916.            BLE.B      2$
  1917.            MOVE.W      D4,ws_Bottom(A3)
  1918.  
  1919. * ------------ Anything more to check
  1920. 2$           MOVE.L      A5,D0
  1921.            BNE.W      Check
  1922.  
  1923.            MOVEM.L      (SP)+,D2-D7/A2-A3/A5-A6
  1924.            MOVEQ.L      #TRUE,D0
  1925.            RTS
  1926.  
  1927. *****************************************
  1928. * SelectItem() - Do selection           *
  1929. *****************************************
  1930. @SelectItem:   MOVEM.L     D2-D3/A2-A3/A5,-(SP)
  1931. ********************
  1932. * Check subwindow. *
  1933. ********************
  1934. * ------------ SubWindow.BitMapOk == TRUE ?
  1935.            LEA     _SubWindow(A4),A2
  1936.            TST.W     (A2)                  * wwd_BitMapOk
  1937.            BEQ.B     CheckItem     * No
  1938.  
  1939. * ------------ NewSubItem = FindMouseItem(&SubWindow)
  1940.            MOVEA.L     A2,A0
  1941.            JSR     @FindMouseItem(PC)
  1942.            MOVEA.L     D0,A3
  1943.  
  1944. ********************
  1945. * A2 = SubWindow   *
  1946. * A3 = NewSubItem  *
  1947. ********************
  1948. * ------------ NewSubItem == SubWindow.Current ?
  1949.            MOVEA.L     wwd_Current(A2),A0
  1950.            CMPA.L     A0,A3
  1951.            BEQ.B     4$           * Yes
  1952. ***********************
  1953. * A0 = CurrentSubItem *
  1954. * A2 = SubWindow      *
  1955. * A3 = NewSubItem     *
  1956. ***********************
  1957.  
  1958. * ------------ SubWindow.Current == NULL ?
  1959.            MOVE.L     A0,D0
  1960.            BEQ.B     1$           * Yes
  1961.  
  1962. * ------------ HighLightItem(&SubWindow,HIGHLIGHTOFF)
  1963.            MOVEQ.L     #1,D0
  1964.            MOVEA.L     A2,A0
  1965.            JSR     @HighLightItem(PC)
  1966.            BRA.B     2$
  1967.  
  1968. * ------------ TempItem == NULL ?
  1969. 1$           MOVE.L     _TempItem(A4),D2
  1970.            BEQ.B     2$           * Yes
  1971.  
  1972. * ------------ ItemWindow.Current = TempItem.
  1973.            MOVE.L     D2,_ItemWindow+wwd_Current(A4)
  1974.  
  1975. * ------------ TempItem = NULL.
  1976.            CLR.L     _TempItem(A4)
  1977.  
  1978. * ------------ HighLightCurrItemBehind(HIGHLIGHTON)
  1979.            MOVEQ.L     #0,D0
  1980.            JSR     @HighLightCurrItemBehind(PC)
  1981.  
  1982. * ------------ SubWindow.Current = NewSubItem.
  1983. 2$           MOVE.L     A3,wwd_Current(A2)
  1984.  
  1985. * ------------ SubWindow.Current == NULL ?
  1986.            BEQ.B     3$           * Yes
  1987.  
  1988. * ------------ HighLightItem(&SubWindow,HIGHLIGHTON)
  1989.            MOVEQ.L     #0,D0
  1990.            MOVEA.L     A2,A0
  1991.            JSR     @HighLightItem(PC)
  1992.  
  1993. * ------------ Options & CLICKMENUES ?
  1994.            BTST     #CLICKMENUES,_Options(A4)
  1995.            BEQ.W     SelectDone    * No
  1996.  
  1997. * ------------ Selectable item ?
  1998.            TST.W     D0
  1999.            BEQ.W     SelectDone    * No
  2000.  
  2001. * ------------ return TRUE
  2002.            MOVEQ.L     #TRUE,D0
  2003.            BRA.W     SelectQuit
  2004.  
  2005. * ------------ HighLightCurrItemBehind(HIGHLIGHTOFF)
  2006. 3$           MOVEQ.L     #1,D0
  2007.            JSR     @HighLightCurrItemBehind(PC)
  2008.  
  2009. * ------------ TempItem = ItemWindow.Current.
  2010.            MOVE.L     _ItemWindow+wwd_Current(A4),_TempItem(A4)
  2011.  
  2012. * ------------ ItemWindow.Current = NULL.
  2013.            CLR.L     _ItemWindow+wwd_Current(A4)
  2014.  
  2015. * ------------ Mouse in SubWindow ?
  2016. 4$           MOVEA.L     A2,A0
  2017.            JSR     @MouseInWindow(PC)
  2018.            TST.W     D0
  2019.            BNE.W     SelectDone    * Yes
  2020.  
  2021. *********************
  2022. * Check itemwindow. *
  2023. *********************
  2024. * ------------ ItemWindow.BitMapOk == TRUE ?
  2025. CheckItem:     LEA     _ItemWindow(A4),A3
  2026.            TST.W     (A3)
  2027.            BEQ.W     CheckMenu     * No
  2028.  
  2029. * ------------ Mouse in ItemWindow ?
  2030.            MOVEA.L     A3,A0
  2031.            JSR     @MouseInWindow(PC)
  2032.            TST.W     D0
  2033.            BEQ.W     3$           * No
  2034.  
  2035. * ------------ NewItem = FindMouseItem(&ItemWindow).
  2036.            MOVEA.L     A3,A0
  2037.            JSR     @FindMouseItem(PC)
  2038.            MOVEA.L     D0,A5
  2039.  
  2040.            MOVE.L     wwd_Current(A3),D2
  2041.  
  2042. ***************************************
  2043. * A2 = SubWindow     D2 = CurrentItem *
  2044. * A3 = ItemWindow              *
  2045. * A5 = NewItem                  *
  2046. ***************************************
  2047.  
  2048. * ------------ NewItem == CurrentItem ?
  2049.            CMP.L     D2,A5
  2050.            BEQ.W     SelectDone    * Yes
  2051.  
  2052. * ------------ SubWindow open ?
  2053.            TST.W     (A2)          * wwd_BitMapOk
  2054.            BEQ.B     1$           * No
  2055.  
  2056. * ------------ CloseSubWindow()
  2057.            JSR     @CloseSubWindow(PC)
  2058.  
  2059. * ------------ TempItem = NULL.
  2060.            CLR.L     _TempItem(A4)
  2061.  
  2062. * ------------ CurrentItem == NULL ?
  2063. 1$           TST.L     D2
  2064.            BEQ.B     2$           * Yes
  2065.  
  2066. * ------------ HighLightItem(&ItemWindow,HIGHLIGHTOFF)
  2067.            MOVEQ.L     #1,D0
  2068.            MOVEA.L     A3,A0
  2069.            JSR     @HighLightItem(PC)
  2070.  
  2071. * ------------ ItemWindow.Current = NewItem.
  2072. 2$           MOVE.L     A5,_ItemWindow+wwd_Current(A4)
  2073.  
  2074. * ------------ NewItem == NULL ?
  2075.            MOVE.L     A5,D2
  2076.            BEQ.W     SelectDone    * Yes
  2077.  
  2078. * ------------ HighLightItem(&ItemWindow,HIGHLIGHTON)
  2079.            MOVEQ     #0,D0
  2080.            MOVEA.L     A3,A0
  2081.            JSR     @HighLightItem(PC)
  2082.  
  2083. * ------------ SubWindow.ItemsEnabled = ItemWindow.ItemsEnabled ?
  2084. * ------------    (NewItem->Flags & ITEMENABLED) : 0
  2085.            TST.W     _ItemWindow+wwd_ItemsEnabled(A4)
  2086.            BEQ.B     25$
  2087.            MOVEQ.L     #ITEMENABLED,D1
  2088.            AND.W     mi_Flags(A5),D1
  2089. 25$           MOVE.W     D1,_SubWindow+wwd_ItemsEnabled(A4)
  2090.  
  2091. * ------------ SubWindow.Items = NewItem->SubItem.
  2092.            MOVE.L     mi_SubItem(A5),_SubWindow+wwd_Items(A4)
  2093.  
  2094. * ------------ SubWindow.Items == NULL ?
  2095.            BNE.W     28$           * No
  2096.  
  2097. * ------------ Options & CLICKMENUES ?
  2098.            BTST     #CLICKMENUES,_Options(A4)
  2099.            BEQ.W     SelectDone    * No
  2100.  
  2101. * ------------ Possible to highlight item ?
  2102.            TST.W     D0
  2103.            BEQ.W     SelectDone    * No
  2104.  
  2105. * ------------ return TRUE
  2106.            MOVEQ.L     #TRUE,D0
  2107.            BRA.W     SelectQuit
  2108.  
  2109. * ------------ Open item window
  2110. 28$           MOVE.L     D2,A0
  2111.            MOVE.W     mi_TopEdge(A0),D0
  2112.            SUB.W     _ItemWindow+wwd_TopValue(A4),D0
  2113.            MOVE.W     #$7FFF,D1
  2114.            MOVEA.L     A2,A0
  2115.            MOVEA.L     A3,A1
  2116.            JSR     @OpenItemWindow(PC)
  2117.  
  2118. * ------------ Window opened ?
  2119.            TST.W     D0
  2120.            BEQ.B     29$           * No
  2121.  
  2122. * ------------ Set ISDRAWN bit
  2123.            BSET     #ISDRAWNBIT,mi_Flags(A5)
  2124. 29$           BRA.W     SelectDone
  2125.  
  2126. * ------------ ItemWindow.Current == NULL ?
  2127. 3$           TST.L     wwd_Current(A3)
  2128.            BEQ.B     CheckMenu     * Yes
  2129.  
  2130. * ------------ SubWindow open ?
  2131.            TST.W     (A2)          * wwd_BitMapOk
  2132.            BEQ.B     4$           * No
  2133.  
  2134. * ------------ HighLightCurrItemBehind(HIGHLIGHTOFF)
  2135.            MOVEQ.L     #1,D0
  2136.            JSR     @HighLightCurrItemBehind(PC)
  2137.  
  2138. * ------------ TempItem = ItemWindow.Current.
  2139.            MOVE.L     wwd_Current(A3),_TempItem(A4)
  2140.            BRA.B     5$
  2141.  
  2142. * ------------ HighLightItem(&ItemWindow,HIGHLIGHTOFF)
  2143. 4$           MOVEQ.L     #1,D0
  2144.            MOVEA.L     A3,A0
  2145.            JSR     @HighLightItem(PC)
  2146.  
  2147. * ------------ ItemWindow.Current = NULL.
  2148. 5$           CLR.L     wwd_Current(A3)
  2149.  
  2150. *********************
  2151. * Check menuwindow. *
  2152. *********************
  2153.  
  2154. CheckMenu:     LEA     _MenuWindow(A4),A5
  2155.  
  2156. **********************
  2157. * A2 = SubWindow     *
  2158. * A3 = ItemWindow    *
  2159. * A5 = MenuWindow    *
  2160. **********************
  2161. * ------------ MenuWindow.BitMapOK ?
  2162.            TST.W     (A5)
  2163.            BEQ.W     SelectDone    * No
  2164.  
  2165. * ------------ MouseInWindow(MenuWindow) ?
  2166.            MOVEA.L     A5,A0
  2167.            JSR     @MouseInWindow(PC)
  2168.            TST.W     D0
  2169.            BEQ.W     SelectDone    * No
  2170.  
  2171. * ------------ NewMenuNr = (MouseY - MenuWindow.TopEdge - HBORDERSIZE)/MenuFontSize + 1
  2172.            MOVE.W     _MouseY(A4),D2
  2173.            SUB.W     wwd_TopEdge(A5),D2
  2174.            SUBQ.W     #HBORDERSIZE,D2
  2175.            ANDI.L     #$0000FFFF,D2
  2176.            DIVU.W     _MenuFontSize(A4),D2
  2177.            ADDQ.W     #1,D2
  2178.  
  2179. * ------------ NewMenuNr == CurrentMenuNr ?
  2180.            MOVE.W     _CurrentMenuNr(A4),D3
  2181.            CMP.W     D3,D2
  2182.            BEQ.W     SelectDone    * Yes
  2183.  
  2184. ****************************************
  2185. * A2 = SubWindow    D2 = NewMenuNr     *
  2186. * A3 = ItemWindow   D3 = CurrentMenuNr *
  2187. * A5 = MenuWindow               *
  2188. ****************************************
  2189.  
  2190. * ------------ CurrentMenuNr == 0 ?
  2191.            TST.W     D3
  2192.            BEQ.B     2$           * Yes
  2193.  
  2194. * ------------ ItemWindow.BitMapOk
  2195.            TST.W     (A3)
  2196.            BEQ.B     1$           * No
  2197.  
  2198. * ------------ CloseSubWindow()
  2199.            JSR     @CloseSubWindow(PC)
  2200.  
  2201. * ------------ CloseItemWindow();
  2202.            JSR     @CloseItemWindow(PC)
  2203.  
  2204. * ------------ TempItem = NULL
  2205.            CLR.L     _TempItem(A4)
  2206.  
  2207. * ------------ ToggleMenu(CurrentMenuNr,MenuWindow.Current) - HIGHLIGHTOFF -
  2208. 1$           MOVE.W     D3,D0
  2209.            MOVEA.L     wwd_Current(A5),A0
  2210.            JSR     @ToggleMenu(PC)
  2211.  
  2212. * ------------ MenuWindow.Current = FindMenuPtr(NewMenuNr)
  2213. 2$           MOVE.W     D2,D0
  2214.            JSR     @FindMenuPtr(PC)
  2215.            MOVE.L     D0,wwd_Current(A5)
  2216.  
  2217. * ------------ MenuWindow.Current == NULL ?
  2218.            TST.L     D0
  2219.            BNE.B     3$           * No
  2220.  
  2221. * ------------ CurrentMenuNr = 0
  2222.            CLR.W     _CurrentMenuNr(A4)
  2223.            BRA.B     SelectDone
  2224.  
  2225. * ------------ CurrentMenuNr = LastSelectedNum = NewMenuNr
  2226. 3$           MOVE.W     D2,_CurrentMenuNr(A4)
  2227.            MOVE.W     D2,_LastSelectedNum(A4)
  2228.            MOVE.W     D2,D3
  2229.  
  2230. * ------------ ItemWindow.ItemsEnabled = MenuWindow.Current->Flags & MENUENABLED
  2231.            MOVEA.L     wwd_Current(A5),A0
  2232.            MOVEQ.L     #MENUENABLED,D0
  2233.            AND.W     mu_Flags(A0),D0
  2234.            MOVE.W     D0,wwd_ItemsEnabled(A3)
  2235.  
  2236. * ------------ ItemWindow.Items = MenuWindow.Current->FirstItem
  2237.            MOVE.L     mu_FirstItem(A0),wwd_Items(A3)
  2238.  
  2239. * ------------ ToggleMenu(NewMenuNr,MenuWindow.Current)  - HIGHLIGHTON -
  2240.            MOVE.W     D2,D0
  2241.            JSR     @ToggleMenu(PC)
  2242.  
  2243. * ------------ ItemWindow->Items == NULL ?
  2244.            TST.L     wwd_Items(A3)
  2245.            BEQ.B     SelectDone    * Yes
  2246.  
  2247. * ------------ ItemsTopPos = (CurrentMenuNr - 1) * MenuFontSize + MenuWindow.TopEdge
  2248.            MOVE.W     D3,D0
  2249.            SUBQ.W     #1,D0
  2250.            MULU.W     _MenuFontSize(A4),D0
  2251.            ADD.W     _MenuWindow+wwd_TopEdge(A4),D0
  2252.  
  2253. * ------------ OpenItemWindow(ItemWindow,MenuWindow,ItemsTopPos,ITEMWINDOW)
  2254.            MOVEA.L     A3,A0
  2255.            MOVEA.L     A5,A1
  2256.            MOVEQ.L     #0,D1
  2257.            JSR     @OpenItemWindow(PC)
  2258.  
  2259. * ------------ Window opened ?
  2260.            TST.W     D0
  2261.            BEQ.B     SelectDone    * NO
  2262.  
  2263. * ------------ Set MIDRAWN flag
  2264.            MOVEA.L     wwd_Current(A5),A0
  2265.            BSET     #MIDRAWNBIT,mu_Flags(A0)
  2266.  
  2267. SelectDone:    MOVEQ.L     #FALSE,D0
  2268. SelectQuit:    MOVEM.L     (SP)+,D2-D3/A2-A3/A5
  2269.            RTS
  2270.  
  2271. *****************************************************************
  2272. * FinalSelect() - Do checkmarking and calculate Menupick value. *
  2273. *                                *
  2274. * Input:                            *
  2275. *   none                            *
  2276. * Output:                            *
  2277. *   return  - MenuPick-value or MENUNULL.            *
  2278. *****************************************************************
  2279. @FinalSelect:  MOVEM.L     D6-D7/A2-A3,-(SP)
  2280.  
  2281. * ------------ SubItemNr = NOSUB
  2282.            MOVEQ     #$1F,D7
  2283.  
  2284.            MOVEA.L     _SubWindow+wwd_Current(A4),A2
  2285.            MOVEA.L     _ItemWindow+wwd_Current(A4),A3
  2286.  
  2287. * ------------ SubWindow.Current == NULL ?
  2288.            MOVE.L     A2,D0
  2289.            BEQ.B     1$           * Yes
  2290.  
  2291. * ------------ SubWindow.Current->Flags & SubWindow.ItemsEnabled & ITEMENABLED ?
  2292.            MOVEQ.L     #ITEMENABLED,D0
  2293.            AND.W     mi_Flags(A2),D0
  2294.            AND.W     _SubWindow+wwd_ItemsEnabled(A4),D0
  2295.            BEQ.B     1$           * No
  2296.  
  2297. * ------------ Subitem selected -> checkmark and draw all subitems again.
  2298. * ------------ CheckMark(&SubWindow)
  2299.            LEA     _SubWindow(A4),A0
  2300.            JSR     @CheckMark(PC)
  2301.            TST.W     D0
  2302.            BEQ.B     05$
  2303.  
  2304. * ------------ DrawAllItems(&SubWindow)
  2305.            LEA     _SubWindow(A4),A0
  2306.            JSR     @DrawAllItems(PC)
  2307.  
  2308. * ------------ HighLightItem(&SubWindow,HIGHLIGHTON)
  2309.            MOVEQ.L     #0,D0
  2310.            LEA     _SubWindow(A4),A0
  2311.            JSR     @HighLightItem(PC)
  2312.  
  2313. * ------------ SubWindow.Current->NextSelect = MENUNULL
  2314. 05$           MOVE.W     #$FFFF,mi_NextSelect(A2)
  2315.  
  2316. * ------------ Find the number of the selected subitem
  2317.            MOVEA.L     A2,A0
  2318.            MOVEA.L     _SubWindow+wwd_Items(A4),A1
  2319.            JSR     @FindItemNr(PC)
  2320.            MOVE.L     D0,D7
  2321.            BRA.B     3$
  2322.  
  2323. * ------------ ItemWindow.Current == NULL ?
  2324. 1$           MOVE.L     A3,D0
  2325.            BEQ.B     2$           * Yes
  2326.  
  2327. * ------------ ItemWindow.Current->Flags & ITEMENABLED ?
  2328.            MOVEQ.L     #ITEMENABLED,D0
  2329.            AND.W     mi_Flags(A3),D0
  2330.            BEQ.B     2$           * No
  2331.  
  2332. * ------------ ItemWindow.ItemsEnabled & MENUENABLED ?
  2333.            TST.W     _ItemWindow+wwd_ItemsEnabled(A4)
  2334.            BEQ.B     2$           * No
  2335.  
  2336. * ------------ ItemWindow.Current->SubItem == NULL ?
  2337.            TST.L     mi_SubItem(A3)
  2338.            BNE.B     2$           * No
  2339.  
  2340. * ------------ ItemWindow.Current->NextSelect = MENUNULL
  2341.            MOVE.W     #$FFFF,mi_NextSelect(A3)
  2342.            BRA.B     3$
  2343.  
  2344. * ------------ Nothing is selected -> exit
  2345. 2$           MOVEQ.L     #-1,D0
  2346.            BRA.B     6$
  2347.  
  2348. * ------------ CheckMark(ItemWindow)
  2349. 3$           LEA     _ItemWindow(A4),A0
  2350.            BSR.B     @CheckMark
  2351.            TST.W     D0
  2352.            BEQ.B     38$
  2353.  
  2354. * ------------ Remove SubWindow (if any).
  2355.            LEA     _SubWindow(A4),A0
  2356.            JSR     @SwapBits(PC)
  2357.  
  2358. * ------------ DrawAllItems(&ItemWindow)
  2359.            LEA     _ItemWindow(A4),A0
  2360.            JSR     @DrawAllItems(PC)
  2361.  
  2362. * ------------ Check if ItemWindow & MenuWindow is Same (4.0)
  2363.            TST.W     _MenuWindow(A4)        * BitMapOk
  2364.            BNE.B     35$
  2365.  
  2366. * ------------ DrawAllMenues(ItemWindow)
  2367.            LEA     _ItemWindow(A4),A0
  2368.            JSR     @DrawAllMenues
  2369.  
  2370. * ------------ HighLightItem(&ItemWindow,HIGHLIGHTON)
  2371. 35$           MOVEQ.L     #0,D0
  2372.            LEA     _ItemWindow(A4),A0
  2373.            JSR     @HighLightItem(PC)
  2374.  
  2375. * ------------ Restore subwindow. (if any)
  2376.            LEA     _SubWindow(A4),A0
  2377.            JSR     @SwapBits(PC)
  2378.  
  2379. * ------------ Find number of selected item,
  2380. 38$           MOVEA.L     A3,A0
  2381.            MOVEA.L     _ItemWindow+wwd_Items(A4),A1
  2382.            JSR     @FindItemNr(PC)
  2383.            MOVE.L     D0,D6
  2384.  
  2385. * ------------ MenuNum = SHIFTMENU(FindRealMenuNum(CurrentMenuNr)) |
  2386. * ------------         SHIFTITEM(ItemNr) |
  2387. * ------------         SHIFTSUB(SubItemNr)
  2388.            MOVE.W     _CurrentMenuNr(A4),D0
  2389.  
  2390.            JSR     @FindMenuPtr(PC)
  2391.            MOVEA.L     D0,A1
  2392.            MOVEA.L     _Menues(A4),A0
  2393.  
  2394.            MOVEQ.L     #0,D0
  2395.  
  2396. 4$           CMPA.L     A0,A1
  2397.            BEQ.B     5$
  2398.  
  2399.            MOVEA.L     (A0),A0        * mu_NextMenu(A0)
  2400.            ADDQ.L     #1,D0
  2401.            BRA.B     4$
  2402.  
  2403. * ------------ SHIFTITEM(ItemNr)
  2404. 5$           ANDI.W     #$3F,D6
  2405.            ASL.W     #5,D6
  2406.            OR.W     D6,D0
  2407.  
  2408. * ------------ SHIFTSUB(SubItemNr)
  2409.            ANDI.W     #$1F,D7
  2410.            ASL.W     #8,D7
  2411.            ASL.W     #3,D7
  2412.            OR.W     D7,D0
  2413.  
  2414. 6$           MOVEM.L     (SP)+,D6-D7/A2-A3
  2415.            RTS
  2416.  
  2417. **************************************************
  2418. * CheckMark(Window) - Checkmark selected item.   *
  2419. *                         *
  2420. * Input:                     *
  2421. *   Window     - Window to checkmark         *
  2422. * Output:                     *
  2423. *   return.W   - TRUE if checkmarked         *
  2424. **************************************************
  2425. @CheckMark:    MOVEA.L     wwd_Items(A0),A1
  2426.            MOVEA.L     wwd_Current(A0),A0
  2427.  
  2428.            MOVE.W     mi_Flags(A0),D1
  2429.  
  2430. * ------------ Selected->Flags & CHECKIT ?
  2431.            MOVEQ.L     #CHECKIT,D0
  2432.            AND.W     D1,D0
  2433.            BEQ.B     4$           * No
  2434.  
  2435. * ------------ Selected->Flags & CHECKED ?
  2436.            MOVE.W     #CHECKED,D0
  2437.            AND.W     D1,D0
  2438.            BEQ.B     1$           * No
  2439.  
  2440. * ------------ Selected->Flags & MENUTOGGLE ?
  2441.            MOVEQ.L     #MENUTOGGLE,D0
  2442.            AND.W     D1,D0
  2443.            BEQ.B     4$           * No
  2444.  
  2445. * ------------ Selected->Flags &= ~CHECKED   - Togglemenu -
  2446.            BCLR     #0,mi_Flags(A0)
  2447.            BRA.B     35$
  2448.  
  2449. * ------------ Selected->Flags |= CHECKED
  2450. 1$           BSET     #0,mi_Flags(A0)
  2451.  
  2452. * ------------ Handle mutual exclusion.
  2453. * ------------ Exclude = Selected->MutualExclude
  2454.            MOVE.L     mi_MutualExclude(A0),D0
  2455.            BEQ.B     35$
  2456.  
  2457. * ------------ Exclude >>= 1
  2458. 2$           LSR.L     #1,D0
  2459.            BCC.B     3$
  2460.  
  2461. * ------------ Items->Flags &= ~CHECKED
  2462.            BCLR     #0,mi_Flags(A1)
  2463.  
  2464. * ------------ Items = Items->NextItem
  2465. 3$           MOVEA.L     (A1),A1
  2466.  
  2467. * ------------ More items ?
  2468.            MOVE.L     A1,D1
  2469.            BNE.B     2$           * Yes
  2470.  
  2471. 35$           MOVEQ.L     #TRUE,D0
  2472. 4$           RTS
  2473.  
  2474. ************************************************************
  2475. * DrawMenuItem(Window, Item, Mode)                         *
  2476. *                               *
  2477. * Input:                           *
  2478. *   Window  -      Data about window to draw item into.       *
  2479. *   Item    -      Item to draw.                *
  2480. *   Mode.W  -      ITEMFILL = Draw Item.            *
  2481. *          SELECTFILL = Draw selected item (if any).*
  2482. * OUTPUT                           *
  2483. *   none                           *
  2484. ************************************************************
  2485. @DrawMenuItem: MOVEM.L     D2-D7/A2-A3/A5-A6,-(SP)
  2486.            MOVEA.L     A1,A3
  2487.  
  2488.            MOVE.L     A0,-(SP)
  2489. ********************************************************
  2490. * D0 = Mode          A0 = Window       (SP) Window *
  2491. *              A1 = Item                *
  2492. *              A3 = Item                *
  2493. ********************************************************
  2494. * ------------ Left = Item->LeftEdge - Window->LeftValue
  2495.            MOVE.W     mi_LeftEdge(A3),D7
  2496.            SUB.W     wwd_LeftValue(A0),D7
  2497.            EXT.L     D7
  2498.  
  2499. * ------------ Right = Left + Item->Width - 1
  2500.            MOVE.L     D7,D2
  2501.            ADD.W     mi_Width(A3),D2
  2502.            SUBQ.L     #1,D2
  2503.  
  2504. * ------------ ItemTop = Top = Item->TopEdge - Window->TopValue
  2505.            MOVE.W     mi_TopEdge(A3),D6
  2506.            SUB.W     wwd_TopValue(A0),D6
  2507.            EXT.L     D6
  2508.            MOVE.L     D6,D4
  2509.  
  2510. * ------------ Bottom = Top + Item->Height - 1
  2511.            MOVE.L     D6,D3
  2512.            ADD.W     mi_Height(A3),D3
  2513.            SUBQ.L     #1,D3
  2514.  
  2515.            LEA     _Rp(A4),A5
  2516.            MOVEA.L     _IntuitionBase(A4),A6
  2517.  
  2518. * ------------ Find what to Draw.
  2519.            MOVEA.L     mi_ItemFill(A3),A2
  2520.  
  2521.            TST.W     D0          * Mode == ITEMFILL ?
  2522.            BEQ.B     CheckDraw
  2523.  
  2524. * ------------ Use selectfill.
  2525.            MOVEA.L     mi_SelectFill(A3),A2
  2526.  
  2527. ***************************************************************
  2528. * D0 = Mode             A0 = Window      (SP) Window *
  2529. *                 A1 = Item                  *
  2530. * D2 = Right             A2 = Fill                  *
  2531. * D3 = Bottom             A3 = Item                  *
  2532. * D4 = ItemTop                              *
  2533. * D6 = Top             A5 = Rp                  *
  2534. * D7 = Left             A6 = IntuitionBase           *
  2535. ***************************************************************
  2536. * ------------ Anything to draw ?
  2537. CheckDraw:     MOVE.L     A2,D0
  2538.            BEQ.W     DrawDone
  2539.  
  2540. * ------------ Draw the item.
  2541. DrawItem:      MOVEA.L     A5,A0           * Rp
  2542.            MOVEA.L     A2,A1           * Fill
  2543.            MOVE.L     D7,D0           * Left
  2544.            MOVE.L     D6,D1           * Top
  2545.  
  2546.            MOVEQ.L     #ITEMTEXT,D5
  2547.            AND.W     mi_Flags(A3),D5
  2548.            BEQ.B     DrawImage
  2549.  
  2550. * ------------ PrintIText(Fill, Left, Top)
  2551.            JSR     _LVOPrintIText(A6)
  2552.  
  2553. * ------------ ItemTop    += Fill.TopEdge
  2554.            ADD.W     it_TopEdge(A2),D4
  2555.  
  2556.            BRA.B     DrawCheckMark
  2557.  
  2558. * ------------ DrawImage(Fill, Left, Top)
  2559. DrawImage:     JSR     _LVODrawImage(A6)
  2560.  
  2561. * ------------ ItemTop += Fill.TopEdge
  2562.            ADD.W     ig_TopEdge(A2),D4
  2563.  
  2564. ***********************************************************
  2565. * D2 = Right         A2 = Fill          (SP) Window *
  2566. * D3 = Bottom         A3 = Item              *
  2567. * D4 = ItemTop         A5 = Rp              *
  2568. * D6 = Top         A6 = IntuitionBase          *
  2569. * D7 = Left                          *
  2570. ***********************************************************
  2571. * ------------ Draw CheckMark ?
  2572. DrawCheckMark: MOVE.W     #CHECKIT+CHECKED,D0
  2573.            AND.W     mi_Flags(A3),D0
  2574.            CMPI.W     #CHECKIT+CHECKED,D0
  2575.            BNE.B     DrawCommKey
  2576.  
  2577. * ------------ DrawImage(ActiveWindow->CheckMark, Left, ItemTop)
  2578.            MOVEA.L     _ActiveWindow(A4),A0
  2579.            MOVEA.L     wd_CheckMark(A0),A1   * CheckMark
  2580.            MOVE.L     D7,D0               * Left
  2581.            MOVE.L     D4,D1               * ItemTop (New 3.7)
  2582.            MOVEA.L     A5,A0               * Rp
  2583.            JSR     _LVODrawImage(A6)
  2584.  
  2585. *********************************************
  2586. * D2 = Right         A2 = Fill        *
  2587. * D3 = Bottom         A3 = Item        *
  2588. * D4 = ItemTop         A5 = Rp        *
  2589. * D6 = Top         A6 = IntuitionBase *
  2590. * D7 = Left                    *
  2591. *********************************************
  2592. * ------------ SetDrMd(JAM1)
  2593. DrawCommKey:   MOVEA.L     _GfxBase(A4),A6
  2594.            MOVEA.L     A5,A1               * Rp
  2595.            MOVEQ.L     #RP_JAM1,D0           * JAM1
  2596.            JSR     _LVOSetDrMd(A6)
  2597.  
  2598. * ------------ Has item CommadKey ?
  2599.            MOVEQ.L     #COMMSEQ,D0
  2600.            AND.W     mi_Flags(A3),D0
  2601.            BEQ.B     GhostItem
  2602.  
  2603. * ------------ KeyLeft = Right - Rp.TxWidth
  2604.            MOVE.L     D2,D5
  2605.            SUB.W     _Rp+rp_TxWidth(A4),D5
  2606.  
  2607. *******************************************
  2608. * D2 = Right             A2 = Fill      *
  2609. * D3 = Bottom             A3 = Item      *
  2610. * D4 = ItemTop             A5 = Rp      *
  2611. * D5 = KeyLeft             A6 = GfxBase *
  2612. * D6 = Top                  *
  2613. * D7 = Left                  *
  2614. *******************************************
  2615. * ------------ Move(KeyLeft, ItemTop + Rp.TxHeight - 2);
  2616.            MOVE.L     D5,D0
  2617.            MOVE.L     D4,D1
  2618.            ADD.W     _Rp+rp_TxHeight(A4),D1
  2619.            SUBQ.L     #2,D1
  2620.            MOVEA.L     A5,A1
  2621.            JSR     _LVOMove(A6)
  2622.  
  2623. * ------------ SetAPen(ActiveWindow->DetailPen)
  2624.            MOVEQ     #00,D0
  2625.            MOVEA.L     _ActiveWindow(A4),A0
  2626.            MOVE.B     wd_DetailPen(A0),D0
  2627.            MOVEA.L     A5,A1
  2628.            JSR     _LVOSetAPen(A6)
  2629.  
  2630. * ------------ Text(&Item->Command,1);
  2631.            LEA     mi_Command(A3),A0
  2632.            MOVEA.L     A5,A1
  2633.            MOVEQ     #1,D0
  2634.            JSR     _LVOText(A6)
  2635.  
  2636. * ------------ DrawImage(&MyAmigaKeyImage[ScreenType],KeyLeft, ItemTop);
  2637.            LEA     _MyAmigaKeyImage(PC),A1
  2638.            MOVE.L     D5,D0
  2639.            BSR.B     DrawMyImage
  2640.  
  2641.            MOVEA.L     _GfxBase(A4),A6
  2642.  
  2643. *******************************************
  2644. * D2 = Right             A2 = Fill      *
  2645. * D3 = Bottom             A3 = Item      *
  2646. * D4 = ItemTop             A5 = Rp      *
  2647. * D6 = Top             A6 = GfxBase *
  2648. * D7 = Left                  *
  2649. *******************************************
  2650. * ------------ Ghost Item ?
  2651. GhostItem:     MOVEQ.L     #ITEMENABLED,D0
  2652.            AND.W     mi_Flags(A3),D0
  2653.            BEQ.B     1$
  2654.  
  2655.            MOVEA.L     (SP),A2
  2656.            TST.W     wwd_ItemsEnabled(A2)
  2657.            BNE.B     SubItem
  2658.  
  2659. * ------------ SetAfPt(&Rp, GhostPattern, 1)
  2660. 1$           LEA     _GhostPattern(PC),A0
  2661.            MOVE.L     A0,_Rp+rp_AreaPtrn(A4)
  2662.  
  2663.            MOVE.B     #01,_Rp+rp_AreaPtSz(A4)
  2664.  
  2665. * ------------ SetAPen(ActiveWindow->BlockPen)
  2666.            MOVEQ     #0,D0
  2667.            MOVEA.L     _ActiveWindow(A4),A0
  2668.            MOVE.B     wd_BlockPen(A0),D0
  2669.            MOVEA.L     A5,A1
  2670.            JSR     _LVOSetAPen(A6)
  2671.  
  2672. * ------------ RectFill(Left, Top, Right, Bottom)
  2673.            MOVEA.L     A5,A1
  2674.            MOVE.L     D7,D0
  2675.            MOVE.L     D6,D1
  2676.            JSR     _LVORectFill(A6)
  2677.  
  2678. * ------------ SetAfPt(NormalPattern, 1)
  2679.            LEA     _NormalPattern(PC),A0
  2680.            MOVE.L     A0,_Rp+rp_AreaPtrn(A4)
  2681.  
  2682. *******************************************
  2683. * D2 = Right                  *
  2684. * D3 = Bottom             A3 = Item      *
  2685. * D4 = ItemTop             A5 = Rp      *
  2686. * D6 = Top             A6 = GfxBase *
  2687. * D7 = Left                  *
  2688. *******************************************
  2689. * ------------ SubItem ?
  2690. SubItem:       TST.L     mi_SubItem(A3)
  2691.            BEQ.B     DrawDone
  2692.  
  2693. * ------------ Option & SUBITEMPOINTER
  2694.            BTST     #SUBITEMPOINTER,_Options(A4)
  2695.            BEQ.B     DrawDone
  2696.  
  2697. * ------------ DrawImage(&MySubItemImage[ScreenType],Right,ItemTop);
  2698.            LEA     _MySubItemImage(PC),A1
  2699.            MOVE.L     D2,D0
  2700.            BSR.B     DrawMyImage
  2701.  
  2702. DrawDone:      ADDQ.L     #4,SP
  2703.  
  2704.            MOVEM.L     (SP)+,D2-D7/A2-A3/A5-A6
  2705.            RTS
  2706.  
  2707. ******************************
  2708. * DrawMyImage             *
  2709. * A1 - What to draw         *
  2710. * A5 - Rp             *
  2711. * D0 - Left             *
  2712. * D4 - Top             *
  2713. *                 *
  2714. * Destroyed: D0-D1/A0-A1/A6  *
  2715. ******************************
  2716. DrawMyImage:   TST.W     _ScreenType(A4)
  2717.            BEQ.B     1$
  2718.            MOVEQ.L     #ig_SIZEOF,D1
  2719.            ADDA.L     D1,A1
  2720.  
  2721. 1$           MOVEA.L     A5,A0
  2722.            MOVE.L     D4,D1
  2723.            MOVEA.L     _IntuitionBase(A4),A6
  2724.            JMP     _LVODrawImage(A6)
  2725.  
  2726. ***************************************************
  2727. * HighLightItem(Window, Mode)                     *
  2728. *                          *
  2729. * Input:                      *
  2730. *   Window     -  Data for the window to draw in. *
  2731. *   Mode.W     -  HIGHLIGHTON or HIGHLIGHTOFF.      *
  2732. * Output:                      *
  2733. *   return     -  TRUE if item highlighted      *
  2734. *          (may be HIGHNONE)               *
  2735. ***************************************************
  2736. @HighLightItem:
  2737.            MOVEM.L     D2-D5/A2-A3/A5-A6,-(SP)
  2738.  
  2739.            MOVEA.L     wwd_Current(A0),A3
  2740.  
  2741. * ------------ Possible to highlight item ?
  2742.            MOVEQ.L     #ITEMENABLED,D1
  2743.            AND.W     mi_Flags(A3),D1
  2744.            BEQ.B     1$              * No
  2745.  
  2746.            TST.W     wwd_ItemsEnabled(A0)
  2747.            BNE.B     15$              * Yes
  2748.  
  2749. * ------------ return FALSE
  2750. 1$           MOVEQ.L     #FALSE,D0
  2751.            BRA.W     HighLightQuit
  2752.  
  2753. * ------------ start highlighting
  2754. 15$           MOVEA.L     A0,A2
  2755.  
  2756. * ------------ Start highlighting.
  2757.            LEA     _Rp(A4),A5
  2758.            MOVEA.L     _GfxBase(A4),A6
  2759.  
  2760. * ------------ Set or clear HIGHITEM flag
  2761.            MOVE.W     mi_Flags(A3),D5
  2762.            BCLR     #HIGHITEMBIT,D5
  2763.  
  2764. * ------------ Mode = !Mode
  2765.            MOVEQ.L     #1,D1
  2766.            ADDQ.W     #1,D0
  2767.            AND.W     D1,D0
  2768.  
  2769. * ------------ !Mode = HIGHLIGHTOFF ?
  2770.            BEQ.B     2$           * Yes
  2771.  
  2772.            BSET     #HIGHITEMBIT,D5
  2773.  
  2774. 2$           MOVE.W     D5,mi_Flags(A3)
  2775. ***********************************************
  2776. * D0 = !Mode              A0 = Window     *
  2777. * D5 = Window.Current.Flags   A2 = Window     *
  2778. *                  A3 = Item       *
  2779. *                  A5 = Rp          *
  2780. *                  A6 = GfxBase    *
  2781. ***********************************************
  2782.            AND.W     #HIGHFLAGS,D5
  2783.            BNE.B     NotHighImage
  2784.  
  2785. * ------------ DrawMenuItem(Window, Item, !Mode);
  2786. HighImage:     MOVEA.L     A3,A1
  2787.            JSR     @DrawMenuItem(PC)
  2788.            BRA.B     HighlightDone
  2789.  
  2790. * ------------ SetDrMd(COMPLEMENT)
  2791. NotHighImage:  MOVEQ.L     #RP_COMPLEMENT,D0
  2792.            MOVEA.L     A5,A1
  2793.            JSR     _LVOSetDrMd(A6)
  2794.  
  2795. * ------------ Left   = Item->LeftEdge - Window->LeftValue
  2796.            MOVE.W     mi_LeftEdge(A3),D0
  2797.            SUB.W     wwd_LeftValue(A2),D0
  2798.            EXT.L     D0
  2799.  
  2800. * ------------ Right  = Left + Item->Width - 1
  2801.            MOVE.W     mi_Width(A3),D2
  2802.            EXT.L     D2
  2803.            ADD.L     D0,D2
  2804.            SUBQ.L     #1,D2
  2805.  
  2806. * ------------ Top    = Item->TopEdge - Window->TopValue
  2807.            MOVE.W     mi_TopEdge(A3),D1
  2808.            SUB.W     wwd_TopValue(A2),D1
  2809.            EXT.L     D1
  2810.  
  2811. * ------------ Bottom = Top + Item->Height - 1
  2812.            MOVE.W     mi_Height(A3),D3
  2813.            EXT.L     D3
  2814.            ADD.L     D1,D3
  2815.            SUBQ.L     #1,D3
  2816.  
  2817.            MOVEA.L     A5,A1
  2818.  
  2819. ***********************************
  2820. * D0 = Left              *
  2821. * D1 = Top              *
  2822. * D2 = Right              *
  2823. * D3 = Bottom       A5 = Rp      *
  2824. * D5 = HighFlags   A6 = GfxBase   *
  2825. ***********************************
  2826. * ------------ Check out kind of highlighting.
  2827.            CMPI.W     #HIGHBOX,D5
  2828.            BEQ.B     HighBox
  2829.            CMPI.W     #HIGHCOMP,D5
  2830.            BNE.B     HighlightDone
  2831.  
  2832. * ------------ RectFill(Left, Top, Right, Bottom)
  2833. HighComp:      JSR     _LVORectFill(A6)
  2834.            BRA.B     HighlightDone
  2835.  
  2836. * ------------ DrawRect(Left-4, Top-2, Right + 4, Bottom + 2)
  2837. HighBox:       SUBQ.L     #4,D0
  2838.            SUBQ.L     #2,D1
  2839.            ADDQ.L     #4,D2
  2840.            ADDQ.L     #2,D3
  2841.            JSR     @DrawRect(PC)
  2842.            JSR     @DrawRect(PC)
  2843.  
  2844. * ------------ return TRUE
  2845. HighlightDone: MOVEQ.L     #TRUE,D0
  2846. HighLightQuit: MOVEM.L     (SP)+,D2-D5/A2-A3/A5-A6
  2847.            RTS
  2848.  
  2849. *********************************************
  2850. * ToggleMenu(Number,Menu)                   *
  2851. *                        *
  2852. * Input:                    *
  2853. *   Number.W -    Menu to highlight.        *
  2854. *   Menu   - Pointer to the Menu structure. *
  2855. * Output:                    *
  2856. *   none                    *
  2857. *********************************************
  2858. @ToggleMenu:   MOVEM.L     D2-D3/A6,-(SP)
  2859.  
  2860. * ------------ Menu enabled ?
  2861.            MOVEQ.L     #MENUENABLED,D2
  2862.            AND.W     mu_Flags(A0),D2
  2863.            BEQ.B     ToggleDone
  2864.  
  2865.            MOVE.W     D0,D3
  2866.  
  2867. * ------------ Set drawmode = COMPLEMENT.
  2868.            LEA     _Rp(A4),A1
  2869.            MOVEQ     #RP_COMPLEMENT,D0
  2870.            MOVEA.L     _GfxBase(A4),A6
  2871.            JSR     _LVOSetDrMd(A6)
  2872.  
  2873. * ------------ Invert menu.
  2874. * ------------ Bottom = Number * MenuFontSize + MenuWindow.TopEdge.
  2875.            MOVE.W     _MenuFontSize(A4),D2
  2876.            MULU.W     D2,D3
  2877.            ADD.W     _MenuWindow+wwd_TopEdge(A4),D3
  2878.  
  2879. * ------------ Top = Bottom - MenuFontSize + HBORDERSIZE.
  2880.            MOVE.L     D3,D1
  2881.            SUB.L     D2,D1
  2882.            ADDQ.L     #HBORDERSIZE,D1
  2883.  
  2884. * ------------ Left = MenuWindow.LeftEdge + VBORDERSIZE.
  2885.            MOVEQ.L     #VBORDERSIZE,D0
  2886.            ADD.W     _MenuWindow+wwd_LeftEdge(A4),D0
  2887.  
  2888. * ------------ Right = MenuWindow.RightEdge - VBORDERSIZE.
  2889.            MOVE.W     _MenuWindow+wwd_RightEdge(A4),D2
  2890.            SUBQ.L     #VBORDERSIZE,D2
  2891.  
  2892.            LEA     _Rp(A4),A1
  2893.            JSR     _LVORectFill(A6)
  2894.  
  2895. ToggleDone:    MOVEM.L     (SP)+,D2-D3/A6
  2896.            RTS
  2897.  
  2898. ************************
  2899. * DrawAllMenus(Window) *
  2900. *               *
  2901. ************************
  2902. @DrawAllMenues:
  2903.            MOVEM.L     D2-D4/D7/A2-A3/A5-A6,-(SP)
  2904.  
  2905. * ------------ MenuLeft = Window.LeftEdge + VBORDERSIZE
  2906.            MOVE.W     wwd_LeftEdge(A0),D7                * 4.0
  2907.            ADDQ.W     #VBORDERSIZE,D7
  2908.            EXT.L     D7
  2909.  
  2910. * ------------ MenuTop = Window.TopEdge
  2911.            MOVE.W     wwd_TopEdge(A0),D3                 * 4.0
  2912.            EXT.L     D3
  2913.  
  2914. * ------------ MenuRight = Window.RightEdge - VBORDERSIZE
  2915.            MOVE.W     wwd_RightEdge(A0),D2               * 4.0
  2916.            SUBQ.W     #VBORDERSIZE,D2
  2917.            EXT.L     D2
  2918.  
  2919. * ------------ MenuPtr = MenuSorted;
  2920.            MOVEA.L     _MenuSorted(A4),A3
  2921.            MOVEA.L     _ActiveWindow(A4),A2
  2922.            LEA     _Rp(A4),A5
  2923.            MOVEA.L     _GfxBase(A4),A6
  2924.  
  2925. ****************************************
  2926. * D2 = MenuRight     A2 = ActiveWindow *
  2927. * D3 = MenuTop         A3 = MenuPtr      *
  2928. * D7 = MenuLeft      A5 = Rp           *
  2929. *             A6 = GfxBase      *
  2930. ****************************************
  2931. * ------------ MenuTopOld = MenuTop;
  2932. NextMenu:      MOVE.L     D3,D4
  2933.  
  2934. * ------------ MenuTop += MenuFontSize;
  2935.            ADD.W     _MenuFontSize(A4),D3
  2936.  
  2937. * ------------ SetAPen(Rp,ActiveWindow->DetailPen)
  2938.            MOVEQ.L     #0,D0
  2939.            MOVE.B     wd_DetailPen(A2),D0
  2940.            MOVEA.L     A5,A1
  2941.            JSR     _LVOSetAPen(A6)
  2942.  
  2943. * ------------ Move(Rp, MenuLeft, MenuTop - 1)
  2944.            MOVE.L     D7,D0
  2945.            MOVE.L     D3,D1
  2946.            SUBQ.L     #1,D1
  2947.            MOVEA.L     A5,A1
  2948.            JSR     _LVOMove(A6)
  2949.  
  2950. * ------------ Text(Rp,MenuSorted->MenuPtr->MenuName,Mystrlen(MenuSorted->MenuPtr->MenuName))
  2951.            MOVE.L     ms_MenuPtr(A3),A0
  2952.            MOVEA.L     mu_MenuName(A0),A0
  2953.            MOVE.L     A0,-(SP)
  2954.            JSR     @Mystrlen(PC)
  2955.            MOVEA.L     A5,A1
  2956.            MOVEA.L     (SP)+,A0
  2957.            JSR     _LVOText(A6)
  2958.  
  2959. * ------------ GhostItem ?
  2960.            MOVEQ.L     #MENUENABLED,D0
  2961.            MOVE.L     ms_MenuPtr(A3),A0
  2962.            AND.W     mu_Flags(A0),D0
  2963.            BNE.B     NoMenuGhost
  2964.  
  2965. * ------------ SetAfPt(Rp, GhostPattern, 1)
  2966.            LEA     _GhostPattern(PC),A0
  2967.            MOVE.L     A0,_Rp+rp_AreaPtrn(A4)
  2968.  
  2969.            MOVE.B     #1,_Rp+rp_AreaPtSz(A4)
  2970.  
  2971. * ------------ SetAPen(Rp,ActiveWindow->BlockPen)
  2972.            MOVE.B     wd_BlockPen(A2),D0
  2973.            MOVEA.L     A5,A1
  2974.            JSR     _LVOSetAPen(A6)
  2975.  
  2976. * ------------ RectFill(Rp,MenuLeft,MenuTopOld + HBORDERSIZE,MenuRight,MenuTop)
  2977.            MOVE.L     D7,D0
  2978.            MOVE.L     D4,D1
  2979.            ADDQ.W     #HBORDERSIZE,D1
  2980.            MOVEA.L     A5,A1
  2981.            JSR     _LVORectFill(A6)
  2982.  
  2983. * ------------ SetAfPt(&Rp,NormalPattern,1);
  2984.            LEA     _NormalPattern(PC),A0
  2985.            MOVE.L     A0,_Rp+rp_AreaPtrn(A4)
  2986.  
  2987. * ------------ MenuSaved = MenuSaved->Next
  2988. NoMenuGhost:   MOVEA.L     (A3),A3        * ms_Next(A3)
  2989.  
  2990. * ------------ More menues ?
  2991.            MOVE.L     A3,D0
  2992.            BNE.B     NextMenu
  2993.  
  2994.            MOVEM.L     (SP)+,D2-D4/D7/A2-A3/A5-A6
  2995.            RTS
  2996.  
  2997. **********************************************
  2998. * DrawRect(Rp,Left+2,Top+1,Right-2,Bottom-1) *
  2999. *       A1    D0   D1     D2         D3      *
  3000. **********************************************
  3001. @DrawRect:     MOVEM.L     D4-D5/A5-A6,-(SP)
  3002.  
  3003.            MOVE.L     D0,D4
  3004.            MOVE.L     D1,D5
  3005.            MOVEA.L     A1,A5
  3006.            MOVEA.L     _GfxBase(A4),A6
  3007.  
  3008. * ------------ Move(Rp,Left,Top)
  3009.            JSR     _LVOMove(A6)
  3010.  
  3011. * ------------ Draw(Rp,Left++,Bottom)
  3012.            MOVE.L     D4,D0
  3013.            MOVE.L     D3,D1
  3014.            MOVEA.L     A5,A1
  3015.            JSR     _LVODraw(A6)
  3016.            ADDQ.L     #1,D4
  3017.  
  3018. * ------------ Draw(Rp,Right,Bottom--)
  3019.            MOVE.L     D2,D0
  3020.            MOVE.L     D3,D1
  3021.            MOVEA.L     A5,A1
  3022.            JSR     _LVODraw(A6)
  3023.            SUBQ.L     #1,D3
  3024.  
  3025. * ------------ Draw(Rp,Right--,Top)
  3026.            MOVE.L     D2,D0
  3027.            MOVE.L     D5,D1
  3028.            MOVEA.L     A5,A1
  3029.            JSR     _LVODraw(A6)
  3030.            SUBQ.L     #1,D2
  3031.  
  3032. * ------------ Draw(Rp,Left,Top++)
  3033.            MOVE.L     D4,D0
  3034.            MOVE.L     D5,D1
  3035.            MOVEA.L     A5,A1
  3036.            JSR     _LVODraw(A6)
  3037.            ADDQ.L     #1,D5
  3038.  
  3039. * ------------ Draw(Rp,Left++,Bottom)
  3040.            MOVE.L     D4,D0
  3041.            MOVE.L     D3,D1
  3042.            MOVEA.L     A5,A1
  3043.            JSR     _LVODraw(A6)
  3044.            ADDQ.L     #1,D4
  3045.  
  3046. * ------------ Move(Rp,Right,Bottom)
  3047.            MOVE.L     D2,D0
  3048.            MOVE.L     D3,D1
  3049.            MOVEA.L     A5,A1
  3050.            JSR     _LVOMove(A6)
  3051.  
  3052. * ------------ Draw(Rp,Right--,Top)
  3053.            MOVE.L     D2,D0
  3054.            MOVE.L     D5,D1
  3055.            MOVEA.L     A5,A1
  3056.            JSR     _LVODraw(A6)
  3057.            SUBQ.L     #1,D2
  3058.  
  3059.            MOVE.L     D4,D0
  3060.            MOVE.L     D5,D1
  3061.            MOVEM.L     (SP)+,D4-D5/A5-A6
  3062.            RTS
  3063.  
  3064. * Put these images in the code segment
  3065.  
  3066. _MyAmigaKeyImage:
  3067.            dc.w     -25,0,23,8,1
  3068.            dc.l     _AmigaKeyHighRes
  3069.            dc.b     1,0
  3070.            dc.l     0
  3071.            dc.w     -16,0,14,8,1
  3072.            dc.l     _AmigaKeyLoRes
  3073.            dc.b     1,0
  3074.            dc.l     0
  3075. _MySubItemImage:
  3076.            dc.w     2,0,8,7,1
  3077.            dc.l     _SubItemPointerH
  3078.            dc.b     1,0
  3079.            dc.l     0
  3080.            dc.w     1,0,4,7,1
  3081.            dc.l     _SubItemPointerL
  3082.            dc.b     1,0
  3083.            dc.l     0
  3084.  
  3085. _GhostPattern:    dc.w      $1111,$4444
  3086. _NormalPattern: dc.w      $ffff,$ffff
  3087.  
  3088.            SECTION ImageData,DATA_C
  3089.  
  3090. _AmigaKeyHighRes:
  3091.            dc.l    %11000000000000000000011000000000
  3092.            dc.l    %00000000000000111100000000000000
  3093.            dc.l    %00000000000011111100000000000000
  3094.            dc.l    %00000000001110011100000000000000
  3095.            dc.l    %00000000111000011100000000000000
  3096.            dc.l    %00000011111111111100000000000000
  3097.            dc.l    %00011111100000111111000000000000
  3098.            dc.l    %11000000000000000000011000000000
  3099.  
  3100. _AmigaKeyLoRes:
  3101.            dc.w    %1000000000000100
  3102.            dc.w    %0000000011100000
  3103.            dc.w    %0000000111100000
  3104.            dc.w    %0000001101100000
  3105.            dc.w    %0000011001100000
  3106.            dc.w    %0000111111100000
  3107.            dc.w    %0011110011110000
  3108.            dc.w    %1000000000000100
  3109.  
  3110. _SubItemPointerL:
  3111.            dc.w    %0111000000000000
  3112.            dc.w    %0011000000000000
  3113.            dc.w    %0001000000000000
  3114.            dc.w    %0000000000000000
  3115.            dc.w    %0001000000000000
  3116.            dc.w    %0011000000000000
  3117.            dc.w    %0111000000000000
  3118.  
  3119. _SubItemPointerH:
  3120.            dc.w    %0011111100000000
  3121.            dc.w    %0000111100000000
  3122.            dc.w    %0000001100000000
  3123.            dc.w    %0000000000000000
  3124.            dc.w    %0000001100000000
  3125.            dc.w    %0000111100000000
  3126.            dc.w    %0011111100000000
  3127.            END
  3128.  
  3129.